2 files changed, 61 insertions, 0 deletions
diff --git a/games-engines/devilutionx/Manifest b/games-engines/devilutionx/Manifest
new file mode 100644
index 000000000000..dac3464a12f1
--- /dev/null
+++ b/games-engines/devilutionx/Manifest
@@ -0,0 +1 @@
+DIST devilutionx-1.0.0.tar.gz 1798349 BLAKE2B f2e49e92d8607974dce25ab4de589f01d5603cec4f96e10e55dbdd55b0352ce46d397c91290812dcd8faaa5794c3ab5b23b922098cab9e44dcaf6d049164f6ae SHA512 65eed32e03051880e2e859984911a76c6aae1853cb57491a04090026d6df9cdadf839a0dbb5433691ed1c83cfa7403c72fede38890d494ffd4eff6bef9030c37
diff --git a/games-engines/devilutionx/devilutionx-1.0.0.ebuild b/games-engines/devilutionx/devilutionx-1.0.0.ebuild
new file mode 100644
index 000000000000..6d3bda7a2fb8
--- /dev/null
+++ b/games-engines/devilutionx/devilutionx-1.0.0.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+# Sometimes build with ninja fails.
+# Please check occasionally if we can revert back to ninja.
+# Latest known issue:
+#   https://github.com/diasurgical/devilutionX/issues/490
+CMAKE_MAKEFILE_GENERATOR="emake"
+
+inherit cmake desktop
+
+DESCRIPTION="Diablo engine for modern operating systems"
+HOMEPAGE="https://github.com/diasurgical/devilutionX"
+if [[ "${PV}" == 9999 ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/diasurgical/devilutionX.git"
+else
+	SRC_URI="https://github.com/diasurgical/devilutionX/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/devilutionX-${PV}"
+fi
+
+LICENSE="public-domain"
+SLOT="0"
+
+IUSE="debug"
+
+RDEPEND="
+	dev-libs/libsodium
+	media-libs/libsdl2[haptic]
+	media-libs/sdl2-mixer
+	media-libs/sdl2-ttf
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBINARY_RELEASE=ON
+		-DDEBUG="$(usex debug)"
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	dobin "${BUILD_DIR}/${PN}"
+	make_desktop_entry ${PN} "Diablo devolved"
+}
+
+pkg_postinst() {
+	einfo "In order to play the game you need to install the file"
+	einfo "  diabdat.mpq"
+	einfo "from the original game CD into the following directory:"
+	einfo "  \${HOME}/.local/share/diasurgical/devilution/"
+	einfo "and make sure it's writeable (chmod u+w)."
+}