2 files changed, 85 insertions, 0 deletions
diff --git a/gnome-extra/gnome-packagekit/Manifest b/gnome-extra/gnome-packagekit/Manifest
index cd88fcee95e5..1bf7e6754cb4 100644
--- a/gnome-extra/gnome-packagekit/Manifest
+++ b/gnome-extra/gnome-packagekit/Manifest
@@ -1,2 +1,3 @@
 DIST gnome-packagekit-3.20.0.tar.xz 1801324 SHA256 b84a5db6294ef5252a275b3fcfed509eee60f055ca5d374e5e54d19631c8c571 SHA512 3d356203c9dd3226df1a6a59db39671a85722be550154cf2246233ce74398e608eac97d6f99e9b0d7839620e6e9e72bac64a8efb7388422842b0bcba9d78d8fe WHIRLPOOL 9947ee969bb55cb6078bc42bbcc815ca817ee38350dee912118b6e2fd2444c20ddb12810fd00dbfea8bf95d2fd046c4210e9887148a86127f8b749a91b1101b6
 DIST gnome-packagekit-3.22.1.tar.xz 1684420 SHA256 4064bf32ea649d3f82dd25e4cc91ab0a3f85e03be82a12e54705bd245c3760ef SHA512 f8f5046f53c095f199cf75452a5f0c2cc62a54cd5337b696a3885358573b44d94bcf44b168a4ea8cbd00b746d0274437a5fc9cb10f0a55e9eb9f2dbd2a8e4f18 WHIRLPOOL 445f713db5710b37b59ed444623d84746ef635403d500f9dff5e52900c99ee8c5dbbf5f775f622d171308372d32e59c1795525bb45c917b2526b3b19a8faf578
+DIST gnome-packagekit-3.24.0.tar.xz 2174372 SHA256 8d038681f6879c93f3f58faaa37c41c7ac8cf53eba6b8cb871f5f683ac0bd13f SHA512 af3291b11ad279d050fcd970e1c98257b65da5f36146d8e5f1f255ef1b17e6f2caf8073ce16623da130edaf452860788aa20dd2de6a4bbf639aaf9d3bbd7c095 WHIRLPOOL 2974ebe94259377c6e8ca4d1c29aecf8f1756fbfedc536002753553002716f75b82f4a62c4c737c2b56b34f510d97e10fb0b3600ba6ec4e600e1fc68649ab7a8
diff --git a/gnome-extra/gnome-packagekit/gnome-packagekit-3.24.0.ebuild b/gnome-extra/gnome-packagekit/gnome-packagekit-3.24.0.ebuild
new file mode 100644
index 000000000000..3b3299265a41
--- /dev/null
+++ b/gnome-extra/gnome-packagekit/gnome-packagekit-3.24.0.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit gnome2 virtualx
+
+DESCRIPTION="PackageKit client for the GNOME desktop"
+HOMEPAGE="https://www.freedesktop.org/software/PackageKit/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="systemd udev" # test
+
+# XXX: test, upstream managed to break gpk-self-test beyond repair
+# gdk-pixbuf used in gpk-animated-icon
+# pango used on gpk-common
+RDEPEND="
+	>=dev-libs/glib-2.32:2
+	x11-libs/gdk-pixbuf:2
+	>=x11-libs/gtk+-3.15.3:3
+	>=x11-libs/libnotify-0.7.0:=
+	x11-libs/pango
+
+	>=app-admin/packagekit-base-0.9.1
+	>=media-libs/libcanberra-0.10[gtk3]
+	>=sys-apps/dbus-1.1.2
+
+	media-libs/fontconfig
+	x11-libs/libX11
+
+	systemd? ( >=sys-apps/systemd-42 )
+	!systemd? ( sys-auth/consolekit )
+	udev? ( virtual/libgudev:= )
+"
+DEPEND="${RDEPEND}
+	app-text/docbook-sgml-utils
+	dev-libs/appstream-glib
+	>=dev-util/gtk-doc-am-1.9
+	dev-libs/libxslt
+	>=sys-devel/gettext-0.19.7
+	virtual/pkgconfig
+"
+
+# NOTES:
+# app-text/docbook-sgml-utils required for man pages
+
+# UPSTREAM:
+# see if tests can forget about display (use eclass for that ?)
+
+src_prepare() {
+	# * disable tests with graphical dialogs and that require packagekitd
+	#   to be run with the dummy backend and installed .ui files
+	# * disable tests that fails every time packagekit developers make a
+	#   tiny change to headers
+	# * gpk_test_markdown_func: no definition for that one
+	sed -e '/g_test_add_func.*gpk_test_enum_func/d' \
+		-e '/g_test_add_func.*gpk_test_dbus_task_func/d' \
+		-e '/g_test_add_func.*gpk_test_error_func/d' \
+		-e '/g_test_add_func.*gpk_test_modal_dialog/d' \
+		-e '/g_test_add_func.*gpk_test_task_func/d' \
+		-e '/g_test_add_func.*gpk_test_markdown_func/d' \
+		-i src/gpk-self-test.c || die
+
+	# XXX: g_autoptr requires explicit type support
+	sed -e 's/g_autoptr(GpkTask)/GpkTask */' \
+		-i src/gpk-self-test.c || die
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--localstatedir=/var \
+		--disable-tests \
+		$(use_enable systemd) \
+		$(use_enable udev gudev)
+		# $(use_enable test tests)
+}
+
+src_test() {
+	"${EROOT}${GLIB_COMPILE_SCHEMAS}" --allow-any-name "${S}/data" || die
+	GSETTINGS_SCHEMA_DIR="${S}/data" virtx emake check
+}