1 files changed, 56 insertions, 0 deletions
diff --git a/gui-libs/libhandy/libhandy-1.4.0.ebuild b/gui-libs/libhandy/libhandy-1.4.0.ebuild
new file mode 100644
index 000000000000..8af23d0bf4e6
--- /dev/null
+++ b/gui-libs/libhandy/libhandy-1.4.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnome.org meson xdg vala virtualx
+
+DESCRIPTION="Building blocks for modern adaptive GNOME apps"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/libhandy/"
+
+LICENSE="LGPL-2.1+"
+SLOT="1"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+IUSE="examples glade gtk-doc +introspection test +vala"
+REQUIRED_USE="vala? ( introspection )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/glib-2.44:2
+	>=x11-libs/gtk+-3.24.1:3[introspection?]
+	glade? ( dev-util/glade:3.10= )
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-libs/libxml2:2
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	gtk-doc? ( dev-util/gtk-doc
+		app-text/docbook-xml-dtd:4.3 )
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	use vala && vala_src_prepare
+	xdg_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dprofiling=false # -pg passing
+		$(meson_feature introspection)
+		$(meson_use vala vapi)
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use test tests)
+		$(meson_use examples)
+		$(meson_feature glade glade_catalog)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}