summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
Diffstat (limited to 'kde-plasma/kwallet-pam/kwallet-pam-5.10.5-r1.ebuild')
-rw-r--r--kde-plasma/kwallet-pam/kwallet-pam-5.10.5-r1.ebuild59
1 files changed, 59 insertions, 0 deletions
diff --git a/kde-plasma/kwallet-pam/kwallet-pam-5.10.5-r1.ebuild b/kde-plasma/kwallet-pam/kwallet-pam-5.10.5-r1.ebuild
new file mode 100644
index 000000000000..5798e8eaed59
--- /dev/null
+++ b/kde-plasma/kwallet-pam/kwallet-pam-5.10.5-r1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit kde5
+
+DESCRIPTION="KWallet PAM module to not enter password again"
+LICENSE="LGPL-2.1"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE=""
+
+DEPEND="
+ dev-libs/libgcrypt:0=
+ virtual/pam
+"
+RDEPEND="${DEPEND}
+ net-misc/socat
+"
+
+PATCHES=(
+ "${FILESDIR}/${P}-cleanups.patch"
+ "${FILESDIR}/${P}-check-graphical.patch"
+ "${FILESDIR}/${P}-privileges.patch"
+)
+
+src_configure() {
+ local mycmakeargs=(
+ -DCMAKE_INSTALL_LIBDIR="/$(get_libdir)"
+ -DKWALLET4=0
+ )
+ kde5_src_configure
+}
+
+pkg_postinst() {
+ check_dm() {
+ if [[ -e "${ROOT}${2}" ]] ; then
+ if grep -Eq "auth\s+optional\s+pam_kwallet5.so" "${ROOT}${2}" && \
+ grep -Eq "session\s+optional\s+pam_kwallet5.so" "${ROOT}${2}" ; then
+ elog " ${1} - ${2} ...GOOD"
+ else
+ ewarn " ${1} - ${2} ...BAD"
+ fi
+ fi
+ }
+ elog "This package enables auto-unlocking of kde-frameworks/kwallet:5."
+ elog "List of things to make it work:"
+ elog "1. Use standard blowfish encryption instead of GPG"
+ elog "2. Use same password for login and kwallet"
+ elog "3. A display manager with support for PAM"
+ elog "4.a Have the following lines in the display manager's pam.d file:"
+ elog " -auth optional pam_kwallet5.so"
+ elog " -session optional pam_kwallet5.so auto_start"
+ elog "4.b Checking installed DMs..."
+ has_version "x11-misc/sddm" && check_dm "SDDM" "/etc/pam.d/sddm"
+ has_version "x11-misc/lightdm" && check_dm "LightDM" "/etc/pam.d/lightdm"
+ elog
+ elog "See also: https://wiki.gentoo.org/wiki/KDE#KWallet_auto-unlocking"
+}