summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
Diffstat (limited to 'media-libs/libass/libass-0.11.2.ebuild')
-rw-r--r--media-libs/libass/libass-0.11.2.ebuild46
1 files changed, 46 insertions, 0 deletions
diff --git a/media-libs/libass/libass-0.11.2.ebuild b/media-libs/libass/libass-0.11.2.ebuild
new file mode 100644
index 000000000000..251238af3119
--- /dev/null
+++ b/media-libs/libass/libass-0.11.2.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit eutils multilib-minimal
+
+DESCRIPTION="Library for SSA/ASS subtitles rendering"
+HOMEPAGE="http://github.com/libass/libass"
+SRC_URI="http://github.com/libass/libass/releases/download/${PV}/${P}.tar.xz"
+
+LICENSE="ISC"
+SLOT="0/5" # subslot = libass soname version
+KEYWORDS="alpha amd64 arm hppa ia64 ~mips ppc ppc64 sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
+IUSE="+enca +fontconfig +harfbuzz static-libs"
+
+RDEPEND="fontconfig? ( >=media-libs/fontconfig-2.10.92[${MULTILIB_USEDEP}] )
+ >=media-libs/freetype-2.5.0.1:2[${MULTILIB_USEDEP}]
+ >=virtual/libiconv-0-r1[${MULTILIB_USEDEP}]
+ >=dev-libs/fribidi-0.19.5-r1[${MULTILIB_USEDEP}]
+ harfbuzz? ( >=media-libs/harfbuzz-0.9.12[truetype,${MULTILIB_USEDEP}] )
+ enca? ( >=app-i18n/enca-1.14-r1[${MULTILIB_USEDEP}] )"
+
+DEPEND="${RDEPEND}
+ virtual/pkgconfig"
+
+X86_CPU_OPTS="abi_x86_32 abi_x86_64"
+for i in ${X86_CPU_OPTS} ; do
+ DEPEND="${DEPEND}
+ ${i}? ( dev-lang/yasm )"
+done
+
+DOCS="Changelog"
+
+multilib_src_configure() {
+ ECONF_SOURCE="${S}" econf \
+ $(use_enable enca) \
+ $(use_enable fontconfig) \
+ $(use_enable harfbuzz) \
+ $(use_enable static-libs static)
+}
+
+multilib_src_install_all() {
+ einstalldocs
+ prune_libtool_files
+}