1 files changed, 50 insertions, 0 deletions
diff --git a/media-libs/libfreehand/libfreehand-0.0.0.ebuild b/media-libs/libfreehand/libfreehand-0.0.0.ebuild
new file mode 100644
index 000000000000..d9d3a72f79c4
--- /dev/null
+++ b/media-libs/libfreehand/libfreehand-0.0.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+EGIT_REPO_URI="git://anongit.freedesktop.org/git/libreoffice/libfreehand/"
+inherit base eutils
+[[ ${PV} == 9999 ]] && inherit autotools git-2
+
+DESCRIPTION="Library for import of FreeHand drawings"
+HOMEPAGE="http://www.freedesktop.org/wiki/Software/libfreehand/"
+[[ ${PV} == 9999 ]] || SRC_URI="http://dev-www.libreoffice.org/src/${P}.tar.xz"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+[[ ${PV} == 9999 ]] || \
+KEYWORDS="amd64 ~arm ~ppc x86"
+IUSE="doc static-libs"
+
+RDEPEND="
+	app-text/libwpd:0.9
+	app-text/libwpg:0.2
+	sys-libs/zlib
+"
+DEPEND="${RDEPEND}
+	dev-util/gperf
+	sys-devel/libtool
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+"
+
+src_prepare() {
+	[[ -d m4 ]] || mkdir "m4"
+	base_src_prepare
+	[[ ${PV} == 9999 ]] && eautoreconf
+}
+
+src_configure() {
+	econf \
+		--docdir="${EPREFIX}/usr/share/doc/${PF}" \
+		$(use_enable static-libs static) \
+		--disable-werror \
+		$(use_with doc docs)
+}
+
+src_install() {
+	default
+	prune_libtool_files --all
+}