1 files changed, 50 insertions, 0 deletions
diff --git a/media-libs/libpng/libpng-1.6.38.ebuild b/media-libs/libpng/libpng-1.6.38.ebuild
new file mode 100644
index 000000000000..26f8a8b0427d
--- /dev/null
+++ b/media-libs/libpng/libpng-1.6.38.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit libtool multilib-minimal
+
+DESCRIPTION="Portable Network Graphics library"
+HOMEPAGE="http://www.libpng.org/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.xz
+	apng? ( mirror://sourceforge/apng/${PN}-1.6.37-apng.patch.gz )"
+
+LICENSE="libpng2"
+SLOT="0/16"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris ~x86-winnt"
+IUSE="apng cpu_flags_arm_neon cpu_flags_x86_sse static-libs"
+
+RDEPEND=">=sys-libs/zlib-1.2.8-r1:=[${MULTILIB_USEDEP}]"
+DEPEND="${RDEPEND}"
+
+DOCS=( ANNOUNCE CHANGES libpng-manual.txt README TODO )
+
+src_prepare() {
+	default
+
+	if use apng; then
+		eapply -p0 "${WORKDIR}"/${PN}-*-apng.patch
+
+		# Don't execute symbols check with apng patch, bug #378111
+		sed -i -e '/^check/s:scripts/symbols.chk::' Makefile.in || die
+	fi
+
+	elibtoolize
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		$(use_enable cpu_flags_arm_neon arm-neon check)
+		$(use_enable cpu_flags_x86_sse intel-sse)
+		$(use_enable static-libs static)
+	)
+
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_install_all() {
+	default
+
+	find "${ED}" \( -type f -o -type l \) -name '*.la' -delete || die
+}