1 files changed, 48 insertions, 0 deletions
diff --git a/media-sound/a2jmidid/a2jmidid-12.ebuild b/media-sound/a2jmidid/a2jmidid-12.ebuild
new file mode 100644
index 000000000000..1019f69d4611
--- /dev/null
+++ b/media-sound/a2jmidid/a2jmidid-12.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit meson python-single-r1
+
+DESCRIPTION="Daemon for exposing ALSA sequencer applications in JACK MIDI system"
+HOMEPAGE="https://a2jmidid.ladish.org"
+SRC_URI="https://dl.ladish.org/a2jmidid/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 ~arm x86"
+IUSE="dbus"
+REQUIRED_USE="dbus? ( ${PYTHON_REQUIRED_USE} )"
+
+BDEPEND="
+	virtual/pkgconfig
+"
+CDEPEND="
+	media-libs/alsa-lib
+	virtual/jack
+	dbus? ( sys-apps/dbus ${PYTHON_DEPS} )
+"
+RDEPEND="${CDEPEND}"
+DEPEND="${RDEPEND}"
+
+DOCS=( AUTHORS.rst NEWS.rst README internals.txt )
+
+src_configure() {
+	local emesonargs=(
+		-Ddisable-dbus=$(usex dbus false true)
+	)
+
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	if use dbus; then
+		python_fix_shebang "${ED}"
+	fi
+}