1 files changed, 50 insertions, 0 deletions
diff --git a/net-analyzer/cacti-spine/cacti-spine-99999.ebuild b/net-analyzer/cacti-spine/cacti-spine-99999.ebuild
new file mode 100644
index 000000000000..c378e4a617f4
--- /dev/null
+++ b/net-analyzer/cacti-spine/cacti-spine-99999.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools git-r3
+
+MY_P=${PN}-${PV/_p/-}
+
+DESCRIPTION="Spine is a fast poller for Cacti (formerly known as Cactid)"
+HOMEPAGE="https://cacti.net/spine_info.php"
+EGIT_REPO_URI="https://github.com/Cacti/spine"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS=""
+
+CDEPEND="
+	dev-libs/openssl:0=
+	net-analyzer/net-snmp:=
+	dev-db/mysql-connector-c:0=
+"
+DEPEND="
+	${CDEPEND}
+	sys-apps/help2man
+"
+RDEPEND="
+	${CDEPEND}
+	>net-analyzer/cacti-0.8.8
+"
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.8.8d-ping.patch
+	"${FILESDIR}"/${PN}-0.8.8g-net-snmp.patch
+)
+
+src_prepare() {
+	default
+
+	AT_M4DIR="config" eautoreconf
+}
+
+src_install() {
+	dosbin spine
+
+	insinto /etc/
+	insopts -m0640 -o root
+	newins spine.conf{.dist,}
+
+	doman spine.1
+	dodoc CHANGELOG
+}