summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
Diffstat (limited to 'net-fs/minio/minio-0_pre20180330.ebuild')
-rw-r--r--net-fs/minio/minio-0_pre20180330.ebuild52
1 files changed, 52 insertions, 0 deletions
diff --git a/net-fs/minio/minio-0_pre20180330.ebuild b/net-fs/minio/minio-0_pre20180330.ebuild
new file mode 100644
index 00000000000..987586d8348
--- /dev/null
+++ b/net-fs/minio/minio-0_pre20180330.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit user golang-build golang-vcs-snapshot
+
+EGO_PN="github.com/minio/minio"
+VERSION="2018-03-30T00-38-44Z"
+EGIT_COMMIT="804a4f9c159ecef7093585a5b577e03a382af50e"
+ARCHIVE_URI="https://${EGO_PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+KEYWORDS="~amd64"
+
+DESCRIPTION="An Amazon S3 compatible object storage server"
+HOMEPAGE="https://github.com/minio/minio"
+SRC_URI="${ARCHIVE_URI}"
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE=""
+
+RESTRICT="test"
+
+pkg_setup() {
+ enewgroup ${PN}
+ enewuser ${PN} -1 -1 /var/lib/${PN} ${PN}
+}
+
+src_prepare() {
+ default
+ sed -i -e "s/time.Now().UTC().Format(time.RFC3339)/\"${VERSION}\"/"\
+ -e "s/-s //"\
+ -e "/time/d"\
+ -e "s/+ commitID()/+ \"${EGIT_COMMIT}\"/"\
+ src/${EGO_PN}/buildscripts/gen-ldflags.go || die
+}
+
+src_compile() {
+ pushd src/${EGO_PN} || die
+ MINIO_RELEASE="${VERSION}"
+ go run buildscripts/gen-ldflags.go
+ GOPATH="${S}" go build --ldflags "$(go run buildscripts/gen-ldflags.go)" -o ${PN} || die
+ popd || die
+}
+
+src_install() {
+ pushd src/${EGO_PN} || die
+ dodoc -r README.md CONTRIBUTING.md MAINTAINERS.md docs
+ dobin minio
+ popd || die
+ newinitd "${FILESDIR}"/${PN}.initd ${PN}
+ keepdir /var/{lib,log}/${PN}
+ fowners ${PN}:${PN} /var/{lib,log}/${PN}
+}