summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
Diffstat (limited to 'net-im/signal-cli-bin/signal-cli-bin-0.8.1-r1.ebuild')
-rw-r--r--net-im/signal-cli-bin/signal-cli-bin-0.8.1-r1.ebuild61
1 files changed, 61 insertions, 0 deletions
diff --git a/net-im/signal-cli-bin/signal-cli-bin-0.8.1-r1.ebuild b/net-im/signal-cli-bin/signal-cli-bin-0.8.1-r1.ebuild
new file mode 100644
index 00000000000..e49d162dba0
--- /dev/null
+++ b/net-im/signal-cli-bin/signal-cli-bin-0.8.1-r1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_P="signal-cli-${PV}"
+DESCRIPTION="Send and receive messages of Signal Messenger over a command line interface"
+HOMEPAGE="https://github.com/AsamK/signal-cli/wiki"
+SRC_URI="
+ https://github.com/AsamK/signal-cli/releases/download/v${PV}/${MY_P}.tar.gz -> ${P}.tar.gz
+ https://github.com/AsamK/signal-cli/raw/v${PV}/README.md -> ${P}.README.md
+ https://github.com/AsamK/signal-cli/raw/v${PV}/man/signal-cli.1.adoc -> ${P}.signal-cli.1.adoc
+"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+
+# signal-cli-bin depends on Java 11
+#
+# virtual/jre:11 exists but it's masked with this message:
+# Java 11 is not yet fully supported on Gentoo. Packages cannot depend
+# on it so these virtuals are not yet required. If you wish to use
+# Java 11 then install openjdk-(jdk|jre)-bin directly.
+
+DEPEND="
+ || ( dev-java/openjdk-jre-bin:11 dev-java/openjdk:11 dev-java/openjdk-bin:11 )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+ app-text/asciidoc
+"
+
+PATCHES=(
+ "${FILESDIR}/${P}-use-working-java-version.patch"
+)
+
+src_unpack() {
+ default
+ cp "${DISTDIR}/${P}.signal-cli.1.adoc" signal-cli.1.adoc || die
+}
+
+src_compile() {
+ default
+ a2x --no-xmllint --doctype manpage --format manpage "${WORKDIR}/signal-cli.1.adoc" || die
+}
+
+src_install() {
+ insinto /usr
+ doins -r lib
+ dobin bin/signal-cli
+ newdoc "${DISTDIR}/${P}.README.md" README.md
+ doman "${WORKDIR}/signal-cli.1"
+}
+
+pkg_postinst() {
+ elog "Please read /usr/share/doc/${PF}/README.md.bz2"
+ elog "how to register signal-cli with the signal service and how to send"
+ elog "and receive messages"
+}