summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
Diffstat (limited to 'net-libs/libnfnetlink/libnfnetlink-1.0.2.ebuild')
-rw-r--r--net-libs/libnfnetlink/libnfnetlink-1.0.2.ebuild52
1 files changed, 52 insertions, 0 deletions
diff --git a/net-libs/libnfnetlink/libnfnetlink-1.0.2.ebuild b/net-libs/libnfnetlink/libnfnetlink-1.0.2.ebuild
new file mode 100644
index 00000000000..2480c324f33
--- /dev/null
+++ b/net-libs/libnfnetlink/libnfnetlink-1.0.2.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}"/usr/share/openpgp-keys/netfilter.org.asc
+inherit linux-info verify-sig
+
+DESCRIPTION="The low-level library for netfilter related kernel/userspace communication"
+HOMEPAGE="http://www.netfilter.org/projects/libnfnetlink/"
+SRC_URI="
+ https://www.netfilter.org/projects/${PN}/files/${P}.tar.bz2
+ verify-sig? ( https://www.netfilter.org/projects/${PN}/files/${P}.tar.bz2.sig )"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+BDEPEND="verify-sig? ( sec-keys/openpgp-keys-netfilter )"
+
+pkg_setup() {
+ linux-info_pkg_setup
+
+ if kernel_is lt 2 6 18 ; then
+ ewarn "${PN} requires at least 2.6.18 kernel version"
+ fi
+
+ #netfilter core team has changed some option names with kernel 2.6.20
+ error_common=' is not set when it should be. You can activate it in the Core Netfilter Configuration'
+ if kernel_is lt 2 6 20 ; then
+ CONFIG_CHECK="~IP_NF_CONNTRACK_NETLINK"
+ ERROR_IP_NF_CONNTRACK_NETLINK="CONFIG_IP_NF_CONNTRACK_NETLINK:\t${error_common}"
+ else
+ CONFIG_CHECK="~NF_CT_NETLINK"
+ ERROR_NF_CT_NETLINK="CONFIG_NF_CT_NETLINK:\t${error_common}"
+ fi
+
+ check_extra_config
+}
+
+src_unpack() {
+ default
+
+ use verify-sig && verify-sig_verify_detached "${DISTDIR}"/${P}.tar.bz2{,.sig}
+}
+
+src_install() {
+ default
+
+ # No static archives
+ find "${ED}" -name '*.la' -delete || die
+}