summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
Diffstat (limited to 'net-libs/liboauth/liboauth-1.0.3-r1.ebuild')
-rw-r--r--net-libs/liboauth/liboauth-1.0.3-r1.ebuild80
1 files changed, 80 insertions, 0 deletions
diff --git a/net-libs/liboauth/liboauth-1.0.3-r1.ebuild b/net-libs/liboauth/liboauth-1.0.3-r1.ebuild
new file mode 100644
index 00000000000..96cf577256e
--- /dev/null
+++ b/net-libs/liboauth/liboauth-1.0.3-r1.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="C library implementing the OAuth secure authentication protocol"
+HOMEPAGE="http://liboauth.sourceforge.net/"
+SRC_URI="mirror://sourceforge/project/${PN}/${P}.tar.gz"
+
+LICENSE="|| ( GPL-2 MIT )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x64-macos"
+IUSE="bindist curl doc libressl +nss"
+
+REQUIRED_USE="bindist? ( nss )"
+
+PATCHES=(
+ "${FILESDIR}"/${PN}-1.0.1-doxygen-out-of-tree.patch
+ "${FILESDIR}"/${PN}-1.0.3-openssl-1.1.patch
+)
+
+CDEPEND="
+ curl? ( net-misc/curl )
+ nss? ( dev-libs/nss
+ curl? ( || (
+ net-misc/curl[ssl,curl_ssl_nss]
+ net-misc/curl[-ssl]
+ ) )
+ )
+ !nss? (
+ !libressl? ( dev-libs/openssl:0= )
+ libressl? ( dev-libs/libressl:= )
+ curl? ( || (
+ net-misc/curl[ssl,curl_ssl_openssl]
+ net-misc/curl[-ssl]
+ ) )
+ )
+"
+
+RDEPEND="${CDEPEND}"
+
+DEPEND="
+ ${CDEPEND}
+ doc? (
+ app-doc/doxygen
+ media-gfx/graphviz
+ media-fonts/freefont
+ )
+"
+BDEPEND="
+ virtual/pkgconfig
+"
+
+src_configure() {
+ local myeconfargs=(
+ --disable-static
+ $(use_enable !curl curl)
+ $(use_enable curl libcurl)
+ $(use_enable nss)
+ )
+ econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+ default
+
+ if use doc ; then
+ # make sure fonts are found
+ export DOTFONTPATH="${EPREFIX}"/usr/share/fonts/freefont-ttf
+ emake dox
+ fi
+}
+
+DOCS=( AUTHORS ChangeLog LICENSE.OpenSSL README )
+
+src_install() {
+ use doc && HTML_DOCS=( doc/html/. )
+ default
+ find "${ED}" -name "*.la" -delete || die
+}