1 files changed, 44 insertions, 0 deletions
diff --git a/net-libs/stem/stem-1.5.4.ebuild b/net-libs/stem/stem-1.5.4.ebuild
new file mode 100644
index 000000000000..bc86ace4f3f8
--- /dev/null
+++ b/net-libs/stem/stem-1.5.4.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=(python{2_7,3_4})
+
+inherit vcs-snapshot distutils-r1
+
+DESCRIPTION="Stem is a Python controller library for Tor"
+HOMEPAGE="https://stem.torproject.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~mips ~ppc ~ppc64 ~x86 ~x86-fbsd"
+IUSE="test"
+
+DEPEND="test? ( dev-python/mock[${PYTHON_USEDEP}]
+	net-misc/tor )
+	dev-python/setuptools[${PYTHON_USEDEP}]"
+
+RDEPEND="net-misc/tor"
+
+DOCS=( docs/{_static,_templates,api,tutorials,{change_log,api,contents,download,faq,index,tutorials}.rst} )
+
+python_prepare_all() {
+	# Disable failing test
+	sed -i -e "/test_expand_path/a \
+		\ \ \ \ return" test/integ/util/system.py || die
+	sed -i -e "/test_parsing_with_example/a \
+		\ \ \ \ return" test/unit/manual.py || die
+	sed -i -e "/test_parsing_with_unknown_options/a \
+		\ \ \ \ return" test/unit/manual.py || die
+	sed -i -e "/test_saving_manual/a \
+		\ \ \ \ return" test/unit/manual.py || die
+	sed -i -e "/test_sdist_matches_git/a \
+		\ \ \ \ return" test/integ/installation.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	${PYTHON} run_tests.py --all --target RUN_ALL || die
+}