summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
Diffstat (limited to 'net-libs/zeromq/zeromq-4.2.5.ebuild')
-rw-r--r--net-libs/zeromq/zeromq-4.2.5.ebuild61
1 files changed, 61 insertions, 0 deletions
diff --git a/net-libs/zeromq/zeromq-4.2.5.ebuild b/net-libs/zeromq/zeromq-4.2.5.ebuild
new file mode 100644
index 00000000000..5d8ebac8b7f
--- /dev/null
+++ b/net-libs/zeromq/zeromq-4.2.5.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+inherit autotools
+
+DESCRIPTION="A brokerless kernel"
+HOMEPAGE="http://www.zeromq.org/"
+SRC_URI="https://github.com/zeromq/libzmq/releases/download/v${PV}/${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0/5"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
+IUSE="doc pgm +sodium static-libs test unwind elibc_Darwin"
+
+RDEPEND="
+ !elibc_Darwin? ( unwind? ( sys-libs/libunwind ) )
+ sodium? ( dev-libs/libsodium:= )
+ pgm? ( =net-libs/openpgm-5.2.122 )"
+DEPEND="${RDEPEND}
+ !elibc_Darwin? ( sys-apps/util-linux )
+ doc? (
+ app-text/asciidoc
+ app-text/xmlto
+ )
+ pgm? ( virtual/pkgconfig )"
+
+PATCHES=()
+
+src_prepare() {
+ sed \
+ -e '/libzmq_werror=/s:yes:no:g' \
+ -i configure.ac || die
+ default
+ eautoreconf
+}
+
+src_configure() {
+ local myeconfargs=(
+ --enable-shared
+ $(use_enable static-libs static)
+ $(use_enable unwind libunwind)
+ $(use_with sodium libsodium)
+ $(use_with pgm)
+ $(use_with doc docs)
+ )
+ econf "${myeconfargs[@]}"
+}
+
+src_test() {
+ # Restricting to one job because multiple tests are using the same port.
+ # Upstream knows the problem and says it doesn't support parallel test
+ # execution, see ${S}/INSTALL.
+ emake -j1 check
+}
+
+src_install() {
+ default
+ find "${ED}"usr/lib* -name '*.la' -delete || die
+}