summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
Diffstat (limited to 'net-wireless')
-rw-r--r--net-wireless/blueman/Manifest1
-rw-r--r--net-wireless/blueman/blueman-2.2.1.ebuild131
2 files changed, 0 insertions, 132 deletions
diff --git a/net-wireless/blueman/Manifest b/net-wireless/blueman/Manifest
index 601f09f59b92..1c344ecfbf1f 100644
--- a/net-wireless/blueman/Manifest
+++ b/net-wireless/blueman/Manifest
@@ -1,2 +1 @@
-DIST blueman-2.2.1.tar.xz 1570992 BLAKE2B b6d2296b68990c25e6d8077b513ebd3915152522fdf66bb5d887a90cf98e8835d993caf89a93089947ff1f6470075b9b6643ee0169ba86e46d190c09fbc6942a SHA512 7668a68470e7b5ab8e5cd774c89a7ae347de4193e293b5f2a467407fcb625e07a482f986fd7b672b763c297a0c0692c1da53dcc4ae75ec7fa118b180be623104
DIST blueman-2.2.2.tar.xz 1560516 BLAKE2B fb82044971fb51ed7732f7638872e3bdbc7259a4fd4f3cc26f5567cfce378319ef3346376d3f07ceab92d2d002ff6455cc7c43345da7f660c3dc9f6b5ab57980 SHA512 b95f82c8a1bc8a77755f56944852a92da3bb58ecf646da75cfc6b6b50af679a3a8efb881f7917e6bb8b3645b1d3ab95b52ecd3c13ff0891ce999b59fe6d24488
diff --git a/net-wireless/blueman/blueman-2.2.1.ebuild b/net-wireless/blueman/blueman-2.2.1.ebuild
deleted file mode 100644
index dccbae5e252b..000000000000
--- a/net-wireless/blueman/blueman-2.2.1.ebuild
+++ /dev/null
@@ -1,131 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI="7"
-
-PYTHON_COMPAT=( python3_{8..9} )
-inherit autotools gnome2-utils linux-info python-single-r1 systemd xdg-utils
-
-DESCRIPTION="Simple and intuitive GTK+ Bluetooth Manager"
-HOMEPAGE="https://github.com/blueman-project/blueman"
-
-if [[ ${PV} == "9999" ]] ; then
- inherit git-r3
- EGIT_REPO_URI="https://github.com/blueman-project/blueman.git"
-else
- SRC_URI="https://github.com/blueman-project/${PN}/releases/download/${PV/_/.}/${P/_/.}.tar.xz"
- S=${WORKDIR}/${P/_/.}
- KEYWORDS="amd64 arm arm64 ppc ppc64 x86"
-fi
-
-# icons are GPL-2
-# source files are mixed GPL-3+ and GPL-2+
-LICENSE="GPL-3+ GPL-2"
-SLOT="0"
-IUSE="appindicator network nls policykit pulseaudio"
-
-DEPEND="
- $(python_gen_cond_dep '
- dev-python/pygobject:3[${PYTHON_USEDEP}]
- ')
- >=net-wireless/bluez-5:=
- ${PYTHON_DEPS}"
-BDEPEND="
- $(python_gen_cond_dep '
- dev-python/cython[${PYTHON_USEDEP}]
- ')
- virtual/pkgconfig
- nls? ( dev-util/intltool sys-devel/gettext )"
-RDEPEND="${DEPEND}
- $(python_gen_cond_dep '
- dev-python/pycairo[${PYTHON_USEDEP}]
- ')
- sys-apps/dbus
- x11-libs/gtk+:3[introspection]
- x11-libs/libnotify[introspection]
- || (
- x11-themes/adwaita-icon-theme
- x11-themes/faenza-icon-theme
- x11-themes/mate-icon-theme
- )
- appindicator? ( dev-libs/libappindicator:3[introspection] )
- network? (
- net-firewall/iptables
- || (
- sys-apps/net-tools
- sys-apps/iproute2
- )
- || (
- net-dns/dnsmasq
- net-misc/dhcp
- >=net-misc/networkmanager-0.8
- )
- )
- policykit? ( sys-auth/polkit )
- pulseaudio? (
- || (
- media-sound/pulseaudio[bluetooth]
- media-sound/pulseaudio-modules-bt
- )
- )
-"
-
-REQUIRED_USE="${PYTHON_REQUIRED_USE}"
-
-pkg_pretend() {
- if use network; then
- local CONFIG_CHECK="~BRIDGE ~IP_NF_IPTABLES
- ~IP_NF_NAT ~IP_NF_TARGET_MASQUERADE"
- check_extra_config
- fi
-}
-
-pkg_setup() {
- python-single-r1_pkg_setup
-}
-
-src_prepare() {
- default
- # replace py-compile to fix py3
- [[ ${PV} == 9999 ]] && eautoreconf || eautomake
-}
-
-src_configure() {
- local myconf=(
- --disable-runtime-deps-check
- --disable-static
- --with-systemdsystemunitdir="$(systemd_get_systemunitdir)"
- --with-systemduserunitdir="$(systemd_get_userunitdir)"
- --with-dhcp-config="/etc/dhcp/dhcpd.conf"
- $(use_enable appindicator)
- $(use_enable policykit polkit)
- $(use_enable nls)
- $(use_enable pulseaudio)
- # thunar integration is a single data file with no extra deps
- # so install it unconditionally
- --enable-thunar-sendto
- )
- econf "${myconf[@]}"
-}
-
-src_install() {
- default
-
- if use policykit; then
- # Allow users in plugdev group to modify connections
- insinto /usr/share/polkit-1/rules.d
- doins "${FILESDIR}/01-org.blueman.rules"
- fi
-
- find "${D}" -name '*.la' -delete || die
-}
-
-pkg_postinst() {
- xdg_icon_cache_update
- gnome2_schemas_update
-}
-
-pkg_postrm() {
- xdg_icon_cache_update
- gnome2_schemas_update
-}