1 files changed, 54 insertions, 0 deletions
diff --git a/sys-apps/s6/s6-2.11.1.0-r1.ebuild b/sys-apps/s6/s6-2.11.1.0-r1.ebuild
new file mode 100644
index 000000000000..65697c3d13b7
--- /dev/null
+++ b/sys-apps/s6/s6-2.11.1.0-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="skarnet.org's small and secure supervision software suite"
+HOMEPAGE="https://www.skarnet.org/software/s6/"
+SRC_URI="https://www.skarnet.org/software/${PN}/${P}.tar.gz"
+
+LICENSE="ISC"
+SLOT="0/$(ver_cut 1-2)"
+KEYWORDS="amd64 ~arm x86"
+IUSE="+execline static static-libs"
+
+REQUIRED_USE="static? ( static-libs )"
+
+RDEPEND="execline? ( >=dev-lang/execline-2.8.3.0:=[static-libs(-)?] )
+	>=dev-libs/skalibs-2.11.2.0:=[static-libs(-)?]
+"
+DEPEND="${RDEPEND}"
+
+HTML_DOCS=( doc/. )
+
+src_prepare() {
+	default
+
+	# Avoid QA warning for LDFLAGS addition
+	sed -i -e 's/.*-Wl,--hash-style=both$/:/' configure || die
+
+	sed -i -e '/AR := /d' -e '/RANLIB := /d' Makefile || die
+}
+
+src_configure() {
+	tc-export AR CC RANLIB
+
+	local myconf=(
+		--bindir=/bin
+		--dynlibdir=/usr/$(get_libdir)
+		--libdir=/usr/$(get_libdir)/${PN}
+		--with-dynlib=/usr/$(get_libdir)
+		--with-lib=/usr/$(get_libdir)/execline
+		--with-lib=/usr/$(get_libdir)/skalibs
+		--with-sysdeps=/usr/$(get_libdir)/skalibs
+		$(usex execline '' '--disable-execline' )
+		--enable-shared
+		$(use_enable static allstatic)
+		$(use_enable static static-libc)
+		$(use_enable static-libs static)
+	)
+
+	econf "${myconf[@]}"
+}