1 files changed, 37 insertions, 0 deletions
diff --git a/sys-cluster/kubelet/kubelet-1.24.13.ebuild b/sys-cluster/kubelet/kubelet-1.24.13.ebuild
new file mode 100644
index 000000000000..c855f8434257
--- /dev/null
+++ b/sys-cluster/kubelet/kubelet-1.24.13.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit go-module systemd
+
+DESCRIPTION="Kubernetes Node Agent"
+HOMEPAGE="https://kubernetes.io"
+SRC_URI="https://github.com/kubernetes/kubernetes/archive/v${PV}.tar.gz -> kubernetes-${PV}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="hardened selinux"
+
+BDEPEND=">=dev-lang/go-1.18.1"
+RDEPEND="selinux? ( sec-policy/selinux-kubernetes )"
+
+RESTRICT+=" test "
+S="${WORKDIR}/kubernetes-${PV}"
+
+src_compile() {
+	CGO_LDFLAGS="$(usex hardened '-fno-PIC ' '')" \
+	emake -j1 GOFLAGS="" GOLDFLAGS="" LDFLAGS="" WHAT=cmd/${PN}
+}
+
+src_install() {
+	dobin _output/bin/${PN}
+	keepdir /etc/kubernetes/manifests /var/log/kubelet /var/lib/kubelet
+	newinitd "${FILESDIR}"/${PN}.initd ${PN}
+	newconfd "${FILESDIR}"/${PN}.confd ${PN}
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/${PN}.logrotated ${PN}
+	systemd_dounit "${FILESDIR}"/${PN}.service
+	insinto /etc/kubernetes
+	newins "${FILESDIR}"/${PN}.env ${PN}.env
+}