summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
Diffstat (limited to 'www-apps/davical/davical-1.1.9.2.ebuild')
-rw-r--r--www-apps/davical/davical-1.1.9.2.ebuild70
1 files changed, 70 insertions, 0 deletions
diff --git a/www-apps/davical/davical-1.1.9.2.ebuild b/www-apps/davical/davical-1.1.9.2.ebuild
new file mode 100644
index 00000000000..b7cc044e06d
--- /dev/null
+++ b/www-apps/davical/davical-1.1.9.2.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit webapp
+
+DESCRIPTION="A CalDAV and CardDAV Server"
+HOMEPAGE="https://www.davical.org/"
+SRC_URI="https://www.davical.org/downloads/${PN}_${PV}.orig.tar.xz -> ${P}.tar.xz"
+
+LICENSE="GPL-2 GPL-2+ GPL-3+ LGPL-2.1+ LGPL-3+"
+KEYWORDS="~amd64 ~x86"
+IUSE="ldap"
+
+BDEPEND="sys-devel/gettext"
+
+RDEPEND="app-admin/pwgen
+ dev-lang/php:*[calendar,curl,iconv,imap,ldap?,nls,pdo,postgres,xml]
+ dev-perl/DBD-Pg
+ dev-perl/DBI
+ dev-perl/YAML
+ >=dev-php/awl-0.60
+ virtual/httpd-php"
+
+need_httpd
+
+S="${WORKDIR}"
+
+src_compile() {
+ emake built-locale
+}
+
+src_install() {
+ webapp_src_preinst
+
+ einstalldocs
+
+ einfo "Installing web files"
+ insinto "${MY_HTDOCSDIR}"
+ doins -r htdocs/. htdocs/.htaccess
+
+ einfo "Installing main files and i18n"
+ insinto "${MY_HOSTROOTDIR}/${PN}"
+ doins -r inc locale
+ rm "${ED}/${MY_HOSTROOTDIR}/${PN}/inc/always.php.in" || die
+
+ einfo "Installing sql files"
+ insinto "${MY_SQLSCRIPTSDIR}"
+ doins -r dba/.
+
+ insinto /etc/${PN}
+ doins -r config/. "${FILESDIR}/vhost-example"
+
+ webapp_postinst_txt en "${FILESDIR}/postinstall-en.txt"
+ webapp_postupgrade_txt en "${FILESDIR}/postupgrade-en.txt"
+ webapp_src_install
+
+ fperms +x "${MY_SQLSCRIPTSDIR}/create-database.sh"
+ fperms +x "${MY_SQLSCRIPTSDIR}/update-davical-database"
+}
+
+pkg_postinst() {
+ elog "If you are upgrading from a previous version of davical, don't forget to"
+ elog "upgrade the database structure with"
+ elog " cd /usr/share/webapps/davical/${PVR}/sqlscripts/"
+ elog " ./update-davical-database -dbuser xxxxxxx -appuser xxxxxx"
+
+ webapp_pkg_postinst
+}