1 files changed, 98 insertions, 0 deletions
diff --git a/www-apps/nanoc/nanoc-4.11.7.ebuild b/www-apps/nanoc/nanoc-4.11.7.ebuild
new file mode 100644
index 000000000000..de28a28b1206
--- /dev/null
+++ b/www-apps/nanoc/nanoc-4.11.7.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+USE_RUBY="ruby24 ruby25 ruby26"
+
+RUBY_FAKEGEM_EXTRADOC="NEWS.md README.md"
+
+RUBY_FAKEGEM_GEMSPEC="nanoc.gemspec"
+
+inherit ruby-fakegem
+
+DESCRIPTION="nanoc is a simple but very flexible static site generator written in Ruby"
+HOMEPAGE="https://nanoc.ws/"
+SRC_URI="https://github.com/nanoc/nanoc/archive/${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="MIT"
+
+KEYWORDS="~amd64"
+SLOT="0"
+IUSE="${IUSE} minimal"
+
+DEPEND+="test? ( app-text/asciidoc app-text/highlight )"
+
+RUBY_S="${P}/nanoc"
+
+ruby_add_rdepend "!minimal? (
+	dev-ruby/mime-types:*
+	dev-ruby/rack:*
+	www-servers/adsf
+)
+	>=dev-ruby/addressable-2.5
+	>=dev-ruby/colored-1.2:0
+	>=dev-ruby/cri-2.15:0
+	~www-apps/nanoc-core-${PV}
+	>=dev-ruby/parallel-1.12:1
+	>=dev-ruby/tomlrb-1.2:1
+	>=dev-ruby/tty-command-0.8:0
+	>=dev-ruby/tty-file-0.7:0
+	>=dev-ruby/tty-platform-0.2:0
+	>=dev-ruby/tty-which-0.4:0
+"
+
+ruby_add_bdepend "test? (
+	dev-ruby/rspec:3
+	dev-ruby/asciidoctor
+	dev-ruby/fuubar
+	dev-ruby/haml
+	dev-ruby/maruku
+	>=dev-ruby/mocha-0.13
+	dev-ruby/minitest
+	dev-ruby/mustache
+	dev-ruby/pry
+	dev-ruby/rdoc
+	>=dev-ruby/rouge-3.5.1:2
+	dev-ruby/rubypants
+	dev-ruby/systemu
+	dev-ruby/timecop
+	dev-ruby/vcr
+	dev-ruby/webmock
+	dev-ruby/yard
+)
+doc? (
+	dev-ruby/kramdown
+	dev-ruby/rdiscount
+	dev-ruby/yard
+)"
+
+all_ruby_prepare() {
+	# Avoid unneeded development dependencies
+	sed -i -e '/simplecov/,/SimpleCov.formatter/ s:^:#:' test/helper.rb || die
+	sed -i -e '/simplecov/I s:^:#:' \
+		-e '/codecov/I s:^:#:' ../common/spec/spec_helper_head_core.rb || die
+	sed -i -e '/coverall/I s:^:#:' \
+		-e '/rubocop/ s:^:#:' Rakefile || die
+
+	echo "-r ./spec/spec_helper.rb" > .rspec || die
+
+	# Avoid basepath issues when generating gemspec
+	sed -i -e "s:require_relative ':require './:" ${RUBY_FAKEGEM_GEMSPEC} || die
+
+	# Avoid tests requiring a network connection or make assumptions
+	# about the local network environment.
+	rm -f test/checking/checks/test_{css,html}.rb spec/nanoc/cli/commands/view_spec.rb || die
+
+	# Avoid tests for unpackaged dependencies
+	rm spec/nanoc/deploying/fog_spec.rb \
+	   spec/nanoc/filters/less_spec.rb \
+	   test/filters/test_{markaby,rainpress}.rb || die
+
+	# Avoid non-fatal failing tests due to specifics in the environment
+	sed -i -e '145askip "gentoo"' spec/nanoc/cli/error_handler_spec.rb || die
+	sed -i -e '/watches with --watch/askip "gentoo"' spec/nanoc/cli/commands/compile_spec.rb || die
+	sed -i -e '124askip "ordering issues"' -e '168askip "ordering issues"' spec/nanoc/data_sources/filesystem_spec.rb || die
+}
+
+each_ruby_test() {
+	RUBYLIB="${S}/lib" ${RUBY} -S rake spec test_all || die
+}