1 files changed, 63 insertions, 0 deletions
diff --git a/x11-libs/libdrm/libdrm-2.4.82.ebuild b/x11-libs/libdrm/libdrm-2.4.82.ebuild
new file mode 100644
index 000000000000..464b3a444ebf
--- /dev/null
+++ b/x11-libs/libdrm/libdrm-2.4.82.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+XORG_MULTILIB=yes
+inherit xorg-2
+
+DESCRIPTION="X.Org libdrm library"
+HOMEPAGE="https://dri.freedesktop.org/"
+if [[ ${PV} = 9999* ]]; then
+	EGIT_REPO_URI="git://anongit.freedesktop.org/git/mesa/drm"
+else
+	SRC_URI="https://dri.freedesktop.org/${PN}/${P}.tar.bz2"
+fi
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux"
+VIDEO_CARDS="amdgpu exynos freedreno intel nouveau omap radeon tegra vc4 vivante vmware"
+for card in ${VIDEO_CARDS}; do
+	IUSE_VIDEO_CARDS+=" video_cards_${card}"
+done
+
+IUSE="${IUSE_VIDEO_CARDS} libkms valgrind"
+RESTRICT="test" # see bug #236845
+
+RDEPEND=">=dev-libs/libpthread-stubs-0.3-r1:=[${MULTILIB_USEDEP}]
+	video_cards_intel? ( >=x11-libs/libpciaccess-0.13.1-r1:=[${MULTILIB_USEDEP}] )
+	abi_x86_32? ( !app-emulation/emul-linux-x86-opengl[-abi_x86_32(-)] )"
+DEPEND="${RDEPEND}
+	valgrind? ( dev-util/valgrind )"
+
+src_prepare() {
+	if [[ ${PV} = 9999* ]]; then
+		# tests are restricted, no point in building them
+		sed -ie 's/tests //' "${S}"/Makefile.am
+	fi
+	xorg-2_src_prepare
+	epatch_user
+}
+
+src_configure() {
+	XORG_CONFIGURE_OPTIONS=(
+		# Udev is only used by tests now.
+		--disable-udev
+		--disable-cairo-tests
+		$(use_enable video_cards_amdgpu amdgpu)
+		$(use_enable video_cards_exynos exynos-experimental-api)
+		$(use_enable video_cards_freedreno freedreno)
+		$(use_enable video_cards_intel intel)
+		$(use_enable video_cards_nouveau nouveau)
+		$(use_enable video_cards_omap omap-experimental-api)
+		$(use_enable video_cards_radeon radeon)
+		$(use_enable video_cards_tegra tegra-experimental-api)
+		$(use_enable video_cards_vc4 vc4)
+		$(use_enable video_cards_vivante etnaviv-experimental-api)
+		$(use_enable video_cards_vmware vmwgfx)
+		$(use_enable libkms)
+		# valgrind installs its .pc file to the pkgconfig for the primary arch
+		--enable-valgrind=$(usex valgrind auto no)
+	)
+
+	xorg-2_src_configure
+}