1 files changed, 54 insertions, 0 deletions
diff --git a/x11-wm/blackbox/blackbox-0.76-r1.ebuild b/x11-wm/blackbox/blackbox-0.76-r1.ebuild
new file mode 100644
index 000000000000..81e924b915bf
--- /dev/null
+++ b/x11-wm/blackbox/blackbox-0.76-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="A small, fast, full-featured window manager for X"
+HOMEPAGE="https://github.com/bbidulock/blackboxwm"
+SRC_URI="https://github.com/bbidulock/blackboxwm/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="nls truetype debug"
+
+RDEPEND="x11-libs/libXft
+	x11-libs/libXt
+	x11-libs/libX11
+	nls? ( >=sys-devel/gettext-0.20 )
+	truetype? ( media-libs/freetype )"
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto"
+BDEPEND="virtual/pkgconfig"
+
+S="${WORKDIR}"/blackboxwm-${PV}
+
+src_prepare() {
+	sed -e '/AC_DISABLE_SHARED/d' -i configure.ac || die
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--sysconfdir=/etc/X11/${PN} \
+		$(use_enable debug) \
+		$(use_enable nls) \
+		$(use_enable truetype xft)
+}
+
+src_install() {
+	dodir /etc/X11/Sessions
+	echo "/usr/bin/blackbox" > "${D}/etc/X11/Sessions/${PN}"
+	fperms a+x /etc/X11/Sessions/${PN}
+
+	insinto /usr/share/xsessions
+	doins "${FILESDIR}/${PN}.desktop"
+
+	emake DESTDIR="${D}" install
+	dodoc AUTHORS ChangeLog* COMPLIANCE README* TODO
+
+	find "${D}" -name '*.la' -delete || die
+}