1 files changed, 46 insertions, 0 deletions
diff --git a/xfce-base/libxfce4util/libxfce4util-4.13.2.ebuild b/xfce-base/libxfce4util/libxfce4util-4.13.2.ebuild
new file mode 100644
index 000000000000..6686fd3a1762
--- /dev/null
+++ b/xfce-base/libxfce4util/libxfce4util-4.13.2.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit vala
+
+DESCRIPTION="A basic utility library for the Xfce desktop environment"
+HOMEPAGE="https://git.xfce.org/xfce/libxfce4util/"
+SRC_URI="mirror://xfce/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="LGPL-2"
+SLOT="0/7"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~x64-solaris ~x86-solaris"
+IUSE="introspection vala"
+REQUIRED_USE="vala? ( introspection )"
+
+RDEPEND=">=dev-libs/glib-2.30:=
+	introspection? ( dev-libs/gobject-introspection:= )
+	vala? ( $(vala_depend) )"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	dev-util/gtk-doc-am
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+src_prepare() {
+	# stupid vala.eclass...
+	default
+}
+
+src_configure() {
+	local myconf=(
+		$(use_enable introspection)
+		$(use_enable vala)
+	)
+
+	use vala && vala_src_prepare
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+
+	find "${D}" -name '*.la' -delete || die
+}