From 0000a75334d6770a234e2a2e1141aec4009b0667 Mon Sep 17 00:00:00 2001
From: Joonas Niilola <juippis@gmail.com>
Date: Wed, 11 Jul 2018 18:16:15 +0300
Subject: media-libs/imlib2: 1.5.1: EAPI-7 revbump with new USE flags

Added 'doc' for documentation and 'shm' for X shared memory support.
Closes: https://bugs.gentoo.org/660828
Package-Manager: Portage[mgorny]-2.3.36.1
Closes: https://github.com/gentoo/gentoo/pull/9185
---
 media-libs/imlib2/imlib2-1.5.1-r1.ebuild | 72 ++++++++++++++++++++++++++++++++
 media-libs/imlib2/metadata.xml           |  3 ++
 2 files changed, 75 insertions(+)
 create mode 100644 media-libs/imlib2/imlib2-1.5.1-r1.ebuild

diff --git a/media-libs/imlib2/imlib2-1.5.1-r1.ebuild b/media-libs/imlib2/imlib2-1.5.1-r1.ebuild
new file mode 100644
index 000000000000..7457df0e31d6
--- /dev/null
+++ b/media-libs/imlib2/imlib2-1.5.1-r1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit multilib-minimal toolchain-funcs
+
+DESCRIPTION="Version 2 of an advanced replacement library for libraries like libXpm"
+HOMEPAGE="https://www.enlightenment.org/"
+SRC_URI="https://downloads.sourceforge.net/enlightenment/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x64-solaris ~x86-solaris"
+IUSE="bzip2 cpu_flags_x86_mmx cpu_flags_x86_sse2 doc gif jpeg mp3 nls png shm static-libs tiff X zlib"
+
+REQUIRED_USE="shm? ( X )"
+
+RDEPEND="
+	media-libs/freetype:2[${MULTILIB_USEDEP}]
+	bzip2? ( app-arch/bzip2[${MULTILIB_USEDEP}] )
+	gif? ( media-libs/giflib[${MULTILIB_USEDEP}] )
+	jpeg? ( ~virtual/jpeg-0:0=[${MULTILIB_USEDEP}] )
+	mp3? ( media-libs/libid3tag[${MULTILIB_USEDEP}] )
+	nls? ( sys-devel/gettext )
+	png? ( >=media-libs/libpng-1.6.10:0=[${MULTILIB_USEDEP}] )
+	tiff? ( >=media-libs/tiff-4.0.4:0[${MULTILIB_USEDEP}] )
+	X? (
+		x11-libs/libX11[${MULTILIB_USEDEP}]
+		x11-libs/libXext[${MULTILIB_USEDEP}]
+	)
+	zlib? ( sys-libs/zlib[${MULTILIB_USEDEP}] )
+"
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig[${MULTILIB_USEDEP}]
+	X? ( x11-base/xorg-proto )
+"
+
+multilib_src_configure() {
+	local myconf_imlib2=(
+		$(use_with bzip2)
+		$(use_with gif)
+		$(use_with jpeg)
+		$(use_with mp3 id3)
+		$(use_with png)
+		$(use_with shm x-shm-fd)
+		$(use_enable static-libs static)
+		$(use_with tiff)
+		$(use_with X x)
+		$(use_with zlib)
+	)
+
+	# imlib2 has different configure options for x86/amd64 assembly
+	if [[ $(tc-arch) == amd64 ]]; then
+		myconf_imlib2+=( $(use_enable cpu_flags_x86_sse2 amd64) --disable-mmx )
+	else
+		myconf_imlib2+=( --disable-amd64 $(use_enable cpu_flags_x86_mmx mmx) )
+	fi
+
+	ECONF_SOURCE="${S}" \
+	econf "${myconf_imlib2[@]}"
+}
+
+multilib_src_install() {
+	V=1 emake install DESTDIR="${D}"
+
+	use doc && local HTML_DOCS=( "${S}"/doc/. )
+	einstalldocs
+
+	find "${D}" -name '*.la' -delete || die
+}
diff --git a/media-libs/imlib2/metadata.xml b/media-libs/imlib2/metadata.xml
index 1a0d4be94cfd..c95c673b437c 100644
--- a/media-libs/imlib2/metadata.xml
+++ b/media-libs/imlib2/metadata.xml
@@ -8,6 +8,9 @@
   	<email>proxy-maint@gentoo.org</email>
   	<name>Proxy Maintainers</name>
 </maintainer>
+	<use>
+		<flag name="shm">Use MIT shared memory support for X image transfer.</flag>
+	</use>
 <longdescription>
 Imlib 2 is the successor to Imlib. It is not just a newer version - it is a 
 completely new library. Imlib2 can be installed alongside Imlib 1.x without any 
-- 
cgit v1.2.3-18-g5258