From 0675c389989e57f39cd860984cb97f1e8344ac97 Mon Sep 17 00:00:00 2001
From: Mike Frysinger <vapier@chromium.org>
Date: Fri, 31 Jan 2020 18:20:08 -0500
Subject: net-misc/gsutil: version bump to 4.47

Signed-off-by: Mike Frysinger <vapier@gentoo.org>
---
 net-misc/gsutil/Manifest           |  1 +
 net-misc/gsutil/gsutil-4.47.ebuild | 88 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 89 insertions(+)
 create mode 100644 net-misc/gsutil/gsutil-4.47.ebuild

diff --git a/net-misc/gsutil/Manifest b/net-misc/gsutil/Manifest
index b6d1fa829469..6a01425ea98d 100644
--- a/net-misc/gsutil/Manifest
+++ b/net-misc/gsutil/Manifest
@@ -1,2 +1,3 @@
 DIST gsutil_4.41.tar.gz 3685987 BLAKE2B 7586d6c64c87c27e4c5f3e86372bfe6d7fdfbdcbe4146308ed497d86b6e3fb984a79d3f07ba3ed055ac09bfe70eef893b8b764a46921703c48c8e54e49cac7eb SHA512 f96500a4761cb244039ba20ccb328b143134a74822990538585116fe6afa6f9e23cfecc9958e34d5deb4291edc9cbe97c6176b3a0f0136ed6e8e81303b5b8c4a
 DIST gsutil_4.45.tar.gz 3695514 BLAKE2B 9b129ae1e87620b2430368818929fbd884319cd2cf7788275ba556f873b13700b9333c59b753202d8c88a81eaa47e223f39f6ded26adf8d16144324763528886 SHA512 9b21162afcfcd063976be51151d1d51aaeac1a32c2b7d0ee79aaccb28f5202f93623b39ed994bd796ab508a56363fea69429fe42cd770cff3c7c8352a4956212
+DIST gsutil_4.47.tar.gz 3696516 BLAKE2B c3a5e132ffff7b0e2e46cac17b1bd820b1ead63bbca4b80f17227290f25d12cb46e38df4334ffc71d0261f4467c157ed50ac21b25b1c7a58ec4113758c64d75b SHA512 66d150d496789a89acc71238c7554244ad17a8896b26fd7d6ffb6e26ce14c8b2268633f4a48b8abd8aa25b36f2ef4bd15cdde02b37a9ef52843200b0449289bb
diff --git a/net-misc/gsutil/gsutil-4.47.ebuild b/net-misc/gsutil/gsutil-4.47.ebuild
new file mode 100644
index 000000000000..f47278e7a7ee
--- /dev/null
+++ b/net-misc/gsutil/gsutil-4.47.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+PYTHON_COMPAT=( python3_6 )
+DISTUTILS_USE_SETUPTOOLS="rdepend"
+
+inherit distutils-r1
+
+DESCRIPTION="command line tool for interacting with cloud storage services"
+HOMEPAGE="https://github.com/GoogleCloudPlatform/gsutil"
+SRC_URI="http://commondatastorage.googleapis.com/pub/${PN}_${PV}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="test"
+
+RDEPEND="${PYTHON_DEPS}
+	>=dev-python/argcomplete-1.9.4[${PYTHON_USEDEP}]
+	>=dev-python/boto-2.49.0[${PYTHON_USEDEP}]
+	>=dev-python/crcmod-1.7[${PYTHON_USEDEP}]
+	>=dev-python/fasteners-0.14.1[${PYTHON_USEDEP}]
+	>=dev-python/gcs-oauth2-boto-plugin-2.5[${PYTHON_USEDEP}]
+	>=dev-python/google-apitools-0.5.30[${PYTHON_USEDEP}]
+	>=dev-python/google-reauth-python-0.1.0[${PYTHON_USEDEP}]
+	>=dev-python/httplib2-0.11.3[${PYTHON_USEDEP}]
+	>=dev-python/mock-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/monotonic-1.4[${PYTHON_USEDEP}]
+	>=dev-python/oauth2client-4.1.3[${PYTHON_USEDEP}]
+	>=dev-python/pyopenssl-0.13[${PYTHON_USEDEP}]
+	>=dev-python/retry-decorator-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/six-1.12.0[${PYTHON_USEDEP}]
+	>=dev-python/PySocks-1.01[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}/gsutil-4.41-tests.patch"
+)
+
+S="${WORKDIR}/${PN}"
+
+DOCS=( README.md CHANGES.md )
+
+# needs to talk to Google to run tests
+RESTRICT="test"
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+
+	# NB: We don't delete all of boto/ because the tests are imported by the
+	# production code.  The same reason we can't delete gslib/tests/.  We can
+	# delete the main boto library and use the system version though.
+	rm -r gslib/vendored/boto/boto || die
+
+	sed -i \
+		-e 's/mock==/mock>=/' \
+		-e 's/oauth2client==/oauth2client>=/' \
+		-e 's/SocksiPy-branch==/PySocks>=/' \
+		setup.py || die
+	# Sanity check we didn't miss any updates.
+	grep '==' setup.py && die "Need to update version requirements"
+
+	# For debugging purposes, temporarily uncomment this in order to
+	# show hidden tracebacks.
+	#sed -e 's/^  except OSError as e:$/&\n    raise/' \
+	#	-e 's/def _HandleUnknownFailure(e):/&\n  raise/' \
+	#	-i gslib/__main__.py || die
+
+	# create_bucket raised ResponseNotReady
+	sed -i \
+		-e 's/test_cp_unwritable_tracker_file/_&/' \
+		-e 's/test_cp_unwritable_tracker_file_download/_&/' \
+		gslib/tests/test_cp.py || die
+
+	sed -i -E -e 's/(executable_prefix =).*/\1 [sys.executable]/' \
+		gslib/commands/test.py || die
+
+	# IOError: close() called during concurrent operation on the same file object.
+	sed -i -e 's/sys.stderr.close()/#&/' \
+		gslib/tests/testcase/unit_testcase.py || die
+}
+
+python_test() {
+	BOTO_CONFIG=${FILESDIR}/dummy.boto \
+		${PYTHON} gslib/__main__.py test -u || die "tests failed"
+}
-- 
cgit v1.2.3-65-gdbad