From 0991a574e48c11153c5e4cf231de0bb5decabff8 Mon Sep 17 00:00:00 2001
From: Jakov Smolić <jsmolic@gentoo.org>
Date: Mon, 21 Mar 2022 20:15:54 +0100
Subject: app-doc/NaturalDocs: Port to EAPI 8
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Closes: https://bugs.gentoo.org/832265
Signed-off-by: Jakov Smolić <jsmolic@gentoo.org>
---
 app-doc/NaturalDocs/NaturalDocs-1.52-r1.ebuild | 56 --------------------------
 app-doc/NaturalDocs/NaturalDocs-1.52-r2.ebuild | 51 +++++++++++++++++++++++
 2 files changed, 51 insertions(+), 56 deletions(-)
 delete mode 100644 app-doc/NaturalDocs/NaturalDocs-1.52-r1.ebuild
 create mode 100644 app-doc/NaturalDocs/NaturalDocs-1.52-r2.ebuild

diff --git a/app-doc/NaturalDocs/NaturalDocs-1.52-r1.ebuild b/app-doc/NaturalDocs/NaturalDocs-1.52-r1.ebuild
deleted file mode 100644
index 636ab0980ab3..000000000000
--- a/app-doc/NaturalDocs/NaturalDocs-1.52-r1.ebuild
+++ /dev/null
@@ -1,56 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI="5"
-
-inherit perl-module
-
-DESCRIPTION="Extensible, multi-language source code documentation generator"
-HOMEPAGE="http://www.naturaldocs.org/"
-SRC_URI="mirror://sourceforge/naturaldocs/${P}.zip"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~alpha amd64 ~arm ~arm64 ~hppa ~ia64 ppc ppc64 sparc x86"
-
-IUSE=""
-
-RDEPEND="dev-lang/perl"
-DEPEND="${RDEPEND}
-		app-arch/unzip"
-
-S="${WORKDIR}"
-
-src_install() {
-	insinto /usr/share/${PN}
-	doins -r Styles Info JavaScript
-
-	insinto /etc/${PN}
-	doins -r Config/*
-	dosym ../../../etc/${PN} /usr/share/${PN}/Config
-
-	perl_set_version
-	insinto ${VENDOR_LIB}
-	doins -r Modules/NaturalDocs
-	dodir /usr/share/${PN}/Modules
-	dosym ../../../..${VENDOR_LIB}/NaturalDocs /usr/share/${PN}/Modules/NaturalDocs
-
-	exeinto /usr/share/${PN}
-	doexe ${PN}
-
-	# Symlink the Perl script into /usr/bin
-	dodir /usr/bin
-	dosym ../share/${PN}/${PN} /usr/bin/${PN}
-
-	# Documentation
-	dohtml -r Help/*
-	dosym ../doc/${PF}/html /usr/share/${PN}/Help
-}
-
-pkg_preinst() {
-	if [[ -e /usr/share/${PN}/Config && ! -L /usr/share/${PN}/Config ]] ; then
-		mkdir -p /etc/${PN}
-		mv /usr/share/${PN}/Config/* /etc/${PN}/
-		rm -rf /usr/share/${PN}/Config
-	fi
-}
diff --git a/app-doc/NaturalDocs/NaturalDocs-1.52-r2.ebuild b/app-doc/NaturalDocs/NaturalDocs-1.52-r2.ebuild
new file mode 100644
index 000000000000..df30ac907202
--- /dev/null
+++ b/app-doc/NaturalDocs/NaturalDocs-1.52-r2.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit perl-module
+
+DESCRIPTION="Extensible, multi-language source code documentation generator"
+HOMEPAGE="http://www.naturaldocs.org/"
+SRC_URI="mirror://sourceforge/naturaldocs/${P}.zip"
+S="${WORKDIR}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha amd64 ~arm ~arm64 ~hppa ~ia64 ppc ppc64 sparc x86"
+
+BDEPEND="app-arch/unzip"
+
+src_install() {
+	insinto /usr/share/${PN}
+	doins -r Styles Info JavaScript
+
+	insinto /etc/${PN}
+	doins -r Config/.
+	dosym ../../../etc/${PN} /usr/share/${PN}/Config
+
+	perl_set_version
+	insinto ${VENDOR_LIB}
+	doins -r Modules/NaturalDocs
+	dodir /usr/share/${PN}/Modules
+	dosym ../../../..${VENDOR_LIB}/NaturalDocs /usr/share/${PN}/Modules/NaturalDocs
+
+	exeinto /usr/share/${PN}
+	doexe ${PN}
+
+	# Symlink the Perl script into /usr/bin
+	dodir /usr/bin
+	dosym ../share/${PN}/${PN} /usr/bin/${PN}
+
+	# Documentation
+	dodoc -r Help/.
+	dosym ../doc/${PF}/html /usr/share/${PN}/Help
+}
+
+pkg_preinst() {
+	if [[ -e /usr/share/${PN}/Config && ! -L /usr/share/${PN}/Config ]] ; then
+		mkdir -p /etc/${PN}
+		mv /usr/share/${PN}/Config/* /etc/${PN}/
+		rm -rf /usr/share/${PN}/Config
+	fi
+}
-- 
cgit v1.2.3-65-gdbad