From 0a9e2829ddb94fea5cde05b263498eac5aecfcd3 Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Thu, 8 Jun 2023 12:37:37 +0200
Subject: kde-apps/kwave: 23.04.2 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 kde-apps/kwave/Manifest             |  1 +
 kde-apps/kwave/kwave-23.04.2.ebuild | 87 +++++++++++++++++++++++++++++++++++++
 2 files changed, 88 insertions(+)
 create mode 100644 kde-apps/kwave/kwave-23.04.2.ebuild

diff --git a/kde-apps/kwave/Manifest b/kde-apps/kwave/Manifest
index dd1b7fac3597..fa150e4da885 100644
--- a/kde-apps/kwave/Manifest
+++ b/kde-apps/kwave/Manifest
@@ -1,2 +1,3 @@
 DIST kwave-22.12.3.tar.xz 6966024 BLAKE2B 68146b52504445ba97daa750b0728de07b8f9cd2d592ec71668aa3090ad965e038640ab58c8f12d65e097b36ec67e2bde681d6b40ca3dff6c4bee274d0c63192 SHA512 9c54e39176a7a1bb1000c9f459bb05beb8b3d61f13368ae8391b588dc0819c29edac1056d0836bba51fa1e70b218eebc5da2fc365d88d8ce8e1d6680f6c5916b
 DIST kwave-23.04.1.tar.xz 6965096 BLAKE2B 812b7cc8cf95a41a51c2ae83b082533e8ba8cabd237d4290ec286309804af6f4e9a58f28fcc76f51e864ed807a672ca1ebfcdf022cc98e1abf189b443a39eac9 SHA512 3851ed68f9eea576abbe0351e1f7d4aeb924aed721f3426cee1b10a1b4908cf23506affe790d38c4969b16fa0ac0b0f6bbe5832359d438de73e28fe6773f02d2
+DIST kwave-23.04.2.tar.xz 6965220 BLAKE2B e6033e9da98d2e33493e48421d83f3495b179908e71ea467de9ff44eda10108ffeae58e9c0bd3d5937bfce7b711a1e494bd062a0c54ab3da6b0af0895f3323ad SHA512 74ea3c73730a7b7779bb223de6f7a4ed8815317a8c01d6bb77bf4ad06cf3bd6883d84fd8781d28265c198cabf8686df6410908ac8b921c318684bc3983fdb1b9
diff --git a/kde-apps/kwave/kwave-23.04.2.ebuild b/kde-apps/kwave/kwave-23.04.2.ebuild
new file mode 100644
index 000000000000..11a333ca9de7
--- /dev/null
+++ b/kde-apps/kwave/kwave-23.04.2.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=5.106.0
+QTMIN=5.15.9
+inherit ecm gear.kde.org
+
+DESCRIPTION="Sound editor built on KDE Frameworks 5 that can edit many types of audio files"
+HOMEPAGE="https://apps.kde.org/kwave/"
+
+LICENSE="CC-BY-SA-3.0 CC0-1.0 GPL-2+ LGPL-2+ handbook? ( FDL-1.2 ) opus? ( BSD-2 )"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="alsa flac mp3 opus oss pulseaudio +qtmedia vorbis"
+
+RDEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	media-libs/audiofile:=
+	>=sci-libs/fftw-3:=
+	media-libs/libsamplerate
+	alsa? ( media-libs/alsa-lib )
+	flac? ( media-libs/flac:=[cxx] )
+	mp3? (
+		media-libs/id3lib
+		media-libs/libmad
+		|| (
+			media-sound/lame
+			media-sound/toolame
+			media-sound/twolame
+		)
+	)
+	qtmedia? ( >=dev-qt/qtmultimedia-${QTMIN}:5 )
+	opus? (
+		media-libs/libogg
+		media-libs/opus
+	)
+	pulseaudio? ( media-libs/libpulse )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+"
+DEPEND="${RDEPEND}
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+"
+BDEPEND="
+	sys-devel/gettext
+	handbook? ( || (
+		gnome-base/librsvg
+		virtual/imagemagick-tools[png,svg]
+	) )
+"
+
+DOCS=( AUTHORS CHANGES LICENSES README TODO )
+
+src_configure() {
+	local mycmakeargs=(
+		-DDEBUG=$(usex debug)
+		-DWITH_ALSA=$(usex alsa)
+		-DWITH_DOC=$(usex handbook)
+		-DWITH_FLAC=$(usex flac)
+		-DWITH_MP3=$(usex mp3)
+		-DWITH_OGG_VORBIS=$(usex vorbis)
+		-DWITH_OGG_OPUS=$(usex opus)
+		-DWITH_OSS=$(usex oss)
+		-DWITH_PULSEAUDIO=$(usex pulseaudio)
+		-DWITH_QT_AUDIO=$(usex qtmedia)
+	)
+
+	ecm_src_configure
+}
-- 
cgit v1.2.3-65-gdbad