From 0c1aa028da9964fb7e3c7cff623792e9089908a2 Mon Sep 17 00:00:00 2001
From: Miroslav Šulc <fordfrog@gentoo.org>
Date: Wed, 6 Dec 2023 13:43:40 +0100
Subject: media-sound/qtractor: bump to 0.9.37
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>
---
 media-sound/qtractor/Manifest               |   1 +
 media-sound/qtractor/qtractor-0.9.37.ebuild | 109 ++++++++++++++++++++++++++++
 2 files changed, 110 insertions(+)
 create mode 100644 media-sound/qtractor/qtractor-0.9.37.ebuild

diff --git a/media-sound/qtractor/Manifest b/media-sound/qtractor/Manifest
index 61c03140a9b8..2e3f500a62cc 100644
--- a/media-sound/qtractor/Manifest
+++ b/media-sound/qtractor/Manifest
@@ -1,2 +1,3 @@
 DIST qtractor-0.9.35.tar.gz 2548418 BLAKE2B 86ee849dac7dfd2cf071b7477356171736ff23df9bdc431334221f415e01bfac2887869b2bcb29c401f00cf6b85651709646c6e6034d8365f172854c71ca60ea SHA512 8e99a86afb5f1063cc8df8cb38210ca25c271d54e1cbc21daf288072aa48f67da25ffc4b2e953f27975ee9817fb28e64d9d957755aafe246ef7b1b03c958da0f
 DIST qtractor-0.9.36.tar.gz 2573045 BLAKE2B f9c8999a22522706dc6ed4ce00522d335c107f307e13552c6a55004665ec148100830887742598e0ddf7f5787a543127b1b1918636472ea7bb31d278ee32b7af SHA512 62539076d304a3832c0795d8685e370cc4d405326c71218bdde4d550369f6970eac86718642d80bdb78282e5e6afef2646e99054df432cff34d0bd938e825dfb
+DIST qtractor-0.9.37.tar.gz 2610943 BLAKE2B c9d08a12ee239c45f541ec905bed302886286f8587c56307c4325a98ecade249d8332ed9b1cbf6672c776cc12345446e78ad2339598dc7153142653bb5279bdd SHA512 0266dd7659d72971873bb88eabe86dff4190ed5cf2209f382ead8c10703e8dcc0bfcdf7d9414b5e3a234bea814e1729d113cfe98229e9a8f7b25a6a3406fb806
diff --git a/media-sound/qtractor/qtractor-0.9.37.ebuild b/media-sound/qtractor/qtractor-0.9.37.ebuild
new file mode 100644
index 000000000000..a3dd1301de67
--- /dev/null
+++ b/media-sound/qtractor/qtractor-0.9.37.ebuild
@@ -0,0 +1,109 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg
+
+DESCRIPTION="Audio/MIDI multi-track sequencer written in C++ with the Qt framework"
+HOMEPAGE="https://qtractor.sourceforge.io"
+SRC_URI="mirror://sourceforge/qtractor/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="aubio cpu_flags_x86_sse debug dssi ladspa libsamplerate mad osc rubberband vorbis zlib"
+REQUIRED_USE="dssi? ( ladspa )"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig
+"
+DEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	dev-qt/qtx11extras:5
+	media-libs/alsa-lib
+	media-libs/libsndfile
+	media-libs/lilv
+	media-libs/lv2
+	media-libs/suil
+	virtual/jack
+	x11-libs/libxcb:=
+	aubio? ( media-libs/aubio:= )
+	dssi? ( media-libs/dssi )
+	ladspa? ( media-libs/ladspa-sdk )
+	libsamplerate? ( media-libs/libsamplerate )
+	mad? ( media-libs/libmad )
+	osc? ( media-libs/liblo )
+	rubberband? ( media-libs/rubberband )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+	zlib? ( sys-libs/zlib )
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCONFIG_DSSI=$(usex dssi 1 0)
+		-DCONFIG_GRADIENT=1
+		-DCONFIG_JACK_LATENCY=1
+		-DCONFIG_JACK_METADATA=1
+		-DCONFIG_JACK_SESSION=1
+		-DCONFIG_LADSPA=$(usex ladspa 1 0)
+		-DCONFIG_LIBAUBIO=$(usex aubio 1 0)
+		-DCONFIG_LIBLILV=1
+		-DCONFIG_LIBLO=$(usex osc 1 0)
+		-DCONFIG_LIBMAD=$(usex mad 1 0)
+		-DCONFIG_LIBRUBBERBAND=$(usex rubberband 1 0)
+		-DCONFIG_LIBSAMPLERATE=$(usex libsamplerate 1 0)
+		-DCONFIG_LIBVORBIS=$(usex vorbis 1 0)
+		-DCONFIG_LIBZ=$(usex zlib 1 0)
+		-DCONFIG_LV2=1
+		-DCONFIG_LV2_UI_GTK2=0
+		-DCONFIG_NSM=0
+		-DCONFIG_QT6=0
+		-DCONFIG_SSE=$(usex cpu_flags_x86_sse 1 0)
+		-DCONFIG_STACKTRACE=$(usex debug 1 0)
+		-DCONFIG_VESTIGE=1
+		-DCONFIG_VST2=1
+		-DCONFIG_VST3=0
+		-DCONFIG_XUNIQUE=0
+	)
+	# Following options are left to the default
+	# CONFIG_LV2_ATOM
+	# CONFIG_LV2_BUF_SIZE
+	# CONFIG_LV2_CVPORT
+	# CONFIG_LV2_EVENT
+	# CONFIG_LV2_EXTERNAL_UI
+	# CONFIG_LV2_MIDNAM
+	# CONFIG_LV2_OPTIONS
+	# CONFIG_LV2_PARAMETERS
+	# CONFIG_LV2_PATCH
+	# CONFIG_LV2_PORT_EVENT
+	# CONFIG_LV2_PRESETS
+	# CONFIG_LV2_PROGRAMS
+	# CONFIG_LV2_STATE
+	# CONFIG_LV2_STATE_FILES
+	# CONFIG_LV2_STATE_MAKE_PATH
+	# CONFIG_LV2_TIME
+	# CONFIG_LV2_TIME_POSITION
+	# CONFIG_LV2_UI
+	# CONFIG_LV2_UI_IDLE
+	# CONFIG_LV2_UI_REQ_VALUE
+	# CONFIG_LV2_UI_SHOW
+	# CONFIG_LV2_UI_TOUCH
+	# CONFIG_LV2_WORKER
+	# CONFIG_LV2_UI_X11
+	cmake_src_configure
+}
-- 
cgit v1.2.3-65-gdbad