From 265cc5e33337fe455180b07b9982160d6b222a19 Mon Sep 17 00:00:00 2001
From: Sam James <sam@gentoo.org>
Date: Sun, 4 Apr 2021 02:59:22 +0000
Subject: ames-arcade/burgerspace: port to EAPI 7, games.eclass--

Signed-off-by: Sam James <sam@gentoo.org>
---
 .../burgerspace/burgerspace-1.9.2-r1.ebuild        | 52 ++++++++++++++++++++++
 games-arcade/burgerspace/burgerspace-1.9.2.ebuild  | 47 -------------------
 2 files changed, 52 insertions(+), 47 deletions(-)
 create mode 100644 games-arcade/burgerspace/burgerspace-1.9.2-r1.ebuild
 delete mode 100644 games-arcade/burgerspace/burgerspace-1.9.2.ebuild

diff --git a/games-arcade/burgerspace/burgerspace-1.9.2-r1.ebuild b/games-arcade/burgerspace/burgerspace-1.9.2-r1.ebuild
new file mode 100644
index 000000000000..11de206aa181
--- /dev/null
+++ b/games-arcade/burgerspace/burgerspace-1.9.2-r1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="Clone of the 1982 BurgerTime video game by Data East"
+HOMEPAGE="https://perso.b2b2c.ca/~sarrazip/dev/burgerspace.html"
+SRC_URI="https://perso.b2b2c.ca/~sarrazip/dev/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="network"
+RESTRICT="test" # doesn't really test anything
+
+RDEPEND=">=dev-games/flatzebra-0.1.6"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e "/^pkgsounddir/ s:sounds.*:\$(PACKAGE)/sounds:" \
+		-e "/^desktopentrydir/ s:=.*:=/usr/share/applications:" \
+		-e "/^pixmapdir/ s:=.*:=/usr/share/pixmaps:" \
+		src/Makefile.am \
+		|| die
+
+	sed -i \
+		-e "/Categories/s:Application;::" \
+		-e "/Icon/s:\..*::" \
+		-e "/Terminal/s:0:false:" \
+		src/burgerspace.desktop.in \
+		|| die
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_with network)
+}
+
+src_install() {
+	emake -C src DESTDIR="${D}" install
+
+	doman doc/${PN}.6
+	dodoc AUTHORS NEWS README THANKS
+}
diff --git a/games-arcade/burgerspace/burgerspace-1.9.2.ebuild b/games-arcade/burgerspace/burgerspace-1.9.2.ebuild
deleted file mode 100644
index 2dea3767701f..000000000000
--- a/games-arcade/burgerspace/burgerspace-1.9.2.ebuild
+++ /dev/null
@@ -1,47 +0,0 @@
-# Copyright 1999-2019 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=5
-inherit autotools games
-
-DESCRIPTION="Clone of the 1982 BurgerTime video game by Data East"
-HOMEPAGE="https://perso.b2b2c.ca/~sarrazip/dev/burgerspace.html"
-SRC_URI="https://perso.b2b2c.ca/~sarrazip/dev/${P}.tar.gz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="network"
-RESTRICT="test"  # doesn't really test anything
-
-RDEPEND=">=dev-games/flatzebra-0.1.6"
-DEPEND="${RDEPEND}
-	virtual/pkgconfig"
-
-src_prepare() {
-	sed -i \
-		-e "/^pkgsounddir/ s:sounds.*:\$(PACKAGE)/sounds:" \
-		-e "/^desktopentrydir/ s:=.*:=/usr/share/applications:" \
-		-e "/^pixmapdir/ s:=.*:=/usr/share/pixmaps:" \
-		src/Makefile.am \
-		|| die
-	sed -i \
-		-e "/Categories/s:Application;::" \
-		-e "/Icon/s:\..*::" \
-		-e "/Terminal/s:0:false:" \
-		src/burgerspace.desktop.in \
-		|| die
-	eautoreconf
-}
-
-src_configure() {
-	egamesconf \
-		$(use_with network)
-}
-
-src_install() {
-	emake -C src DESTDIR="${D}" install
-	doman doc/${PN}.6
-	dodoc AUTHORS NEWS README THANKS
-	prepgamesdirs
-}
-- 
cgit v1.2.3-65-gdbad