From 29f452fd59bc76c479d09ab39c242ea02a5dc2f4 Mon Sep 17 00:00:00 2001
From: Patrick McLean <chutzpah@gentoo.org>
Date: Wed, 6 Jul 2022 10:50:03 -0700
Subject: app-misc/yq: add 3.0.2

Signed-off-by: Patrick McLean <chutzpah@gentoo.org>
---
 app-misc/yq/Manifest        |  1 +
 app-misc/yq/yq-3.0.2.ebuild | 50 +++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 51 insertions(+)
 create mode 100644 app-misc/yq/yq-3.0.2.ebuild

diff --git a/app-misc/yq/Manifest b/app-misc/yq/Manifest
index e8fb6586b1d4..633ae691ad4b 100644
--- a/app-misc/yq/Manifest
+++ b/app-misc/yq/Manifest
@@ -1,2 +1,3 @@
 DIST yq-2.13.0.tar.gz 21695 BLAKE2B e6d75cde2c298c19616647aeb14f1e34b1a68bb4db1b7e6f4e2619166ef10142ebd405d3c21492e4f5880c46a8d42222ce22b08afec492e97102923e6b838e2d SHA512 fd2722450606175b7d6674407c992f1f542b8b2309fcb33d4eb7d6e3dbc6dbc9e04b3dae7c4c649d814fdffaa18cbd50472672f1d1357fc58c5306de082b353a
 DIST yq-2.14.0.tar.gz 28030 BLAKE2B 07e200524390e938705854c5d1ac4921fbc8f165cdbf8152e36124e52a1c51c70d6d711b67a3dac8c2bbf1f75040466e8d94505aa5f19e388a31bbcdc92e91bd SHA512 77d5d9cefc70fae9f2606434e11c3b14facb68113f6f99017f87acc860684a1b7a94ecf01514e8fa85a6d9cc860df926e13d1ac5bec160e7d057074d758d1d34
+DIST yq-3.0.2.tar.gz 28939 BLAKE2B 146fe302064db21ae3d93224875bb49a49a3392e4be3acb9265c6bac98b754f5e75910e03b9ce0c3f5eaa19dbf959144d9443f24ecb5ecec9382cd85d7d03e8f SHA512 228b8390c6429381cefed32327e502d0f975cd4c3bf7918efad7e8119b5a93b4ff1216fd35117eed46b8282ec6a7314ae1a15028deab45aa3fc2cb5b6d86a777
diff --git a/app-misc/yq/yq-3.0.2.ebuild b/app-misc/yq/yq-3.0.2.ebuild
new file mode 100644
index 000000000000..1a8f2da5f32d
--- /dev/null
+++ b/app-misc/yq/yq-3.0.2.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{9..11} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Command-line YAML processor - jq wrapper for YAML documents"
+HOMEPAGE="https://yq.readthedocs.io/ https://github.com/kislyuk/yq/ https://pypi.org/project/yq/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	app-misc/jq
+	dev-python/argcomplete[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.3.1[${PYTHON_USEDEP}]
+	dev-python/toml[${PYTHON_USEDEP}]
+	dev-python/xmltodict[${PYTHON_USEDEP}]
+"
+DEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/wheel[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/yq-2.13.0-tests.patch"
+)
+
+python_prepare_all() {
+	sed -e 's:unittest.main():unittest.main(verbosity=2):' \
+		-i test/test.py || die
+
+	sed -r -e 's:[[:space:]]*"coverage",:: ; s:[[:space:]]*"flake8",::' \
+		-i setup.py || die
+
+	sed -e '/license_file/ d' -i setup.cfg || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	"${EPYTHON}" test/test.py </dev/null || die "tests failed under ${EPYTHON}"
+}
-- 
cgit v1.2.3-65-gdbad