From 2cda4dbc25ce5861d67199909a7a85a49264b12b Mon Sep 17 00:00:00 2001
From: Lars Wendler <polynomial-c@gentoo.org>
Date: Sun, 12 Jun 2022 01:32:42 +0200
Subject: dev-libs/libinput: Bump to version 1.21.0

Closes: https://bugs.gentoo.org/842996
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>
---
 dev-libs/libinput/Manifest               |  1 +
 dev-libs/libinput/libinput-1.21.0.ebuild | 93 ++++++++++++++++++++++++++++++++
 2 files changed, 94 insertions(+)
 create mode 100644 dev-libs/libinput/libinput-1.21.0.ebuild

diff --git a/dev-libs/libinput/Manifest b/dev-libs/libinput/Manifest
index 8ae9e3a564f3..8c70311bb34c 100644
--- a/dev-libs/libinput/Manifest
+++ b/dev-libs/libinput/Manifest
@@ -1 +1,2 @@
 DIST libinput-1.20.1.tar.gz 983069 BLAKE2B 8e63e286c0c4284f4a61129d8b6394e7ca9f2018c6a2781a7fe4b7389120dcaf5c101ccfb4b0b869afc489999e954ce244213b5d206ff546d698068e738ac853 SHA512 91f6d6957b16d76807b376d4f81333ed16218fd37b090417d03a2e551d1f5b2c734d891d267bcdc4314cd698d7830f2f467389a9af58155e4e97a86002c8db78
+DIST libinput-1.21.0.tar.gz 988650 BLAKE2B 54c63beeff8dee93a52774220b45321d8a94261687b463319fbae9246331b532be7995a5b32c30425b9d0708b2ba69d4b4e83e8dc7ecebe6fb1237b723a266b6 SHA512 510273d68f2d4cfa61564a706b1f334f6bfca0d1c8faf0bb8aa656cf3fbd5e38d79d6fbaa01a20d38bc15777c9afc341e4ed08d35ef367ef3803ce788cbc4a0e
diff --git a/dev-libs/libinput/libinput-1.21.0.ebuild b/dev-libs/libinput/libinput-1.21.0.ebuild
new file mode 100644
index 000000000000..0dfc7b33fd56
--- /dev/null
+++ b/dev-libs/libinput/libinput-1.21.0.ebuild
@@ -0,0 +1,93 @@
+# Copyright 2014-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit meson python-any-r1 udev
+
+DESCRIPTION="Library to handle input devices in Wayland"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/libinput/ https://gitlab.freedesktop.org/libinput/libinput"
+SRC_URI="https://gitlab.freedesktop.org/${PN}/${PN}/-/archive/${PV}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0/10"
+[[ "$(ver_cut 3)" -gt 900 ]] || \
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="doc input_devices_wacom test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	virtual/pkgconfig
+	doc? (
+		$(python_gen_any_dep '
+			dev-python/commonmark[${PYTHON_USEDEP}]
+			dev-python/recommonmark[${PYTHON_USEDEP}]
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			>=dev-python/sphinx_rtd_theme-0.2.4[${PYTHON_USEDEP}]
+		')
+		>=app-doc/doxygen-1.8.3
+		>=media-gfx/graphviz-2.38.0
+	)
+"
+#	test? ( dev-util/valgrind )
+RDEPEND="
+	input_devices_wacom? ( >=dev-libs/libwacom-0.27 )
+	>=dev-libs/libevdev-1.9.902
+	>=sys-libs/mtdev-1.1
+	virtual/libudev:=
+	virtual/udev
+"
+DEPEND="${RDEPEND}
+	test? ( >=dev-libs/check-0.9.10 )"
+
+python_check_deps() {
+	has_version -b "dev-python/commonmark[${PYTHON_USEDEP}]" && \
+	has_version -b "dev-python/recommonmark[${PYTHON_USEDEP}]" && \
+	has_version -b "dev-python/sphinx[${PYTHON_USEDEP}]" && \
+	has_version -b ">=dev-python/sphinx_rtd_theme-0.2.4[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use doc && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	sed "s@, '-Werror'@@" -i meson.build || die #744250
+}
+
+src_configure() {
+	# gui can be built but will not be installed
+	local emesonargs=(
+		-Ddebug-gui=false
+		$(meson_use doc documentation)
+		$(meson_use input_devices_wacom libwacom)
+		$(meson_use test tests)
+		-Dudev-dir="${EPREFIX}$(get_udevdir)"
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	if use doc ; then
+		docinto html
+		dodoc -r "${BUILD_DIR}"/Documentation/.
+	fi
+}
+
+pkg_postinst() {
+	pkgname="dev-python/python-libevdev"
+	if [[ -z "${REPLACING_VERSIONS}" ]] && ! has_version "${pkgname}" ; then
+		einfo "${pkgname} must be installed to use the"
+		einfo "libinput measure and libinput replay tools."
+	fi
+
+	udev_reload
+	udevadm hwdb --update --root="${ROOT}"
+}
+
+pkg_postrm() {
+	udev_reload
+}
-- 
cgit v1.2.3-65-gdbad