From 2e997de2a4ac458cf73f4accc2caba27dac7bbba Mon Sep 17 00:00:00 2001
From: Sam James <sam@gentoo.org>
Date: Mon, 21 Aug 2023 20:37:32 +0100
Subject: dev-libs/libksba: switch to out-of-source builds

Upstream don't support in-source builds.

Signed-off-by: Sam James <sam@gentoo.org>
---
 dev-libs/libksba/libksba-1.6.4-r1.ebuild | 62 ++++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)
 create mode 100644 dev-libs/libksba/libksba-1.6.4-r1.ebuild

diff --git a/dev-libs/libksba/libksba-1.6.4-r1.ebuild b/dev-libs/libksba/libksba-1.6.4-r1.ebuild
new file mode 100644
index 000000000000..d3944853b9a8
--- /dev/null
+++ b/dev-libs/libksba/libksba-1.6.4-r1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# Maintainers should:
+# 1. Join the "Gentoo" project at https://dev.gnupg.org/project/view/27/
+# 2. Subscribe to release tasks like https://dev.gnupg.org/T6159
+# (find the one for the current release then subscribe to it +
+# any subsequent ones linked within so you're covered for a while.)
+
+VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}"/usr/share/openpgp-keys/gnupg.asc
+# in-source builds are not supported: https://dev.gnupg.org/T6313#166339
+inherit toolchain-funcs out-of-source verify-sig libtool
+
+DESCRIPTION="X.509 and CMS (PKCS#7) library"
+HOMEPAGE="https://www.gnupg.org/related_software/libksba"
+SRC_URI="mirror://gnupg/${PN}/${P}.tar.bz2"
+SRC_URI+=" verify-sig? ( mirror://gnupg/${PN}/${P}.tar.bz2.sig )"
+
+LICENSE="LGPL-3+ GPL-2+ GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+IUSE="static-libs"
+
+RDEPEND=">=dev-libs/libgpg-error-1.33"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	sys-devel/bison
+	verify-sig? ( sec-keys/openpgp-keys-gnupg )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.6.0-no-fgrep-ksba-config.patch
+)
+
+src_prepare() {
+	default
+
+	elibtoolize  # necessary on Solaris for shared lib support
+}
+
+my_src_configure() {
+	export CC_FOR_BUILD="$(tc-getBUILD_CC)"
+
+	local myeconfargs=(
+		--disable-valgrind-tests
+		$(use_enable static-libs static)
+
+		GPG_ERROR_CONFIG="${ESYSROOT}/usr/bin/${CHOST}-gpg-error-config"
+		LIBGCRYPT_CONFIG="${ESYSROOT}/usr/bin/${CHOST}-libgcrypt-config"
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+my_src_install() {
+	default
+
+	# People need to use ksba-config for --cflags and --libs
+	find "${ED}" -type f -name '*.la' -delete || die
+}
-- 
cgit v1.2.3-65-gdbad