From 2fbe493222fb71695c2ba1fcb1bce863e3a8dca9 Mon Sep 17 00:00:00 2001
From: Thomas Bracht Laumann Jespersen <t@laumann.xyz>
Date: Tue, 18 Apr 2023 15:17:33 +0200
Subject: dev-ml/ocaml-gettext: drop dev-ml/camomile dep, EAPI 7 -> 8
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Closes: https://bugs.gentoo.org/904506
Signed-off-by: Thomas Bracht Laumann Jespersen <t@laumann.xyz>
Signed-off-by: Maciej Barć <xgqt@gentoo.org>
---
 dev-ml/ocaml-gettext/ocaml-gettext-0.4.2-r1.ebuild | 44 ++++++++++++++++++++++
 dev-ml/ocaml-gettext/ocaml-gettext-0.4.2.ebuild    | 43 ---------------------
 2 files changed, 44 insertions(+), 43 deletions(-)
 create mode 100644 dev-ml/ocaml-gettext/ocaml-gettext-0.4.2-r1.ebuild
 delete mode 100644 dev-ml/ocaml-gettext/ocaml-gettext-0.4.2.ebuild

diff --git a/dev-ml/ocaml-gettext/ocaml-gettext-0.4.2-r1.ebuild b/dev-ml/ocaml-gettext/ocaml-gettext-0.4.2-r1.ebuild
new file mode 100644
index 000000000000..d42dbf39239e
--- /dev/null
+++ b/dev-ml/ocaml-gettext/ocaml-gettext-0.4.2-r1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DUNE_PKG_NAME="gettext"
+inherit dune
+
+DESCRIPTION="Provides support for internationalization of OCaml program"
+HOMEPAGE="https://github.com/gildor478/ocaml-gettext"
+SRC_URI="https://github.com/gildor478/ocaml-gettext/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1-with-linking-exception"
+SLOT="0/${PV}"
+KEYWORDS="amd64 ~x86"
+IUSE="+ocamlopt test"
+RESTRICT="test"  # Tests fail
+
+BDEPEND="
+	>=dev-ml/cppo-1.6.6
+	dev-ml/dune-configurator
+"
+
+RDEPEND="
+	dev-ml/base:=
+	>=dev-ml/ocaml-fileutils-0.4.0:=[ocamlopt=]
+	sys-devel/gettext
+"
+DEPEND="
+	${RDEPEND}
+	test? ( dev-ml/ounit2[ocamlopt=] )
+"
+
+src_prepare() {
+	default
+
+	# Remove dependency on camomile (see
+	# https://github.com/gildor478/ocaml-gettext/issues/14)
+	rm -r src/lib/gettext-camomile || die
+	rm -r test/test-camomile || die
+
+	# Port to dev-ml/ounit2
+	sed -i -e 's/oUnit/ounit2/' test/{,common,test-stub}/dune || die
+}
diff --git a/dev-ml/ocaml-gettext/ocaml-gettext-0.4.2.ebuild b/dev-ml/ocaml-gettext/ocaml-gettext-0.4.2.ebuild
deleted file mode 100644
index fea75c4363e8..000000000000
--- a/dev-ml/ocaml-gettext/ocaml-gettext-0.4.2.ebuild
+++ /dev/null
@@ -1,43 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-DUNE_PKG_NAME="gettext"
-inherit dune
-
-DESCRIPTION="Provides support for internationalization of OCaml program"
-HOMEPAGE="https://github.com/gildor478/ocaml-gettext"
-SRC_URI="https://github.com/gildor478/ocaml-gettext/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="LGPL-2.1-with-linking-exception"
-SLOT="0/${PV}"
-KEYWORDS="amd64 ~x86"
-IUSE="+ocamlopt test"
-RESTRICT="!test? ( test )"
-
-BDEPEND="
-	>=dev-ml/cppo-1.6.6
-	dev-ml/dune-configurator
-"
-RDEPEND="
-	dev-ml/base:=
-	>=dev-ml/camomile-0.8.3:=[ocamlopt=]
-	>=dev-ml/ocaml-fileutils-0.4.0:=[ocamlopt=]
-	sys-devel/gettext
-"
-DEPEND="
-	${RDEPEND}
-	test? ( dev-ml/ounit2[ocamlopt=] )
-"
-
-src_prepare() {
-	default
-
-	# Port to dev-ml/ounit2
-	sed -i -e 's/oUnit/ounit2/' test/{,common,test-camomile,test-stub}/dune || die
-}
-
-src_install() {
-	dune_src_install
-}
-- 
cgit v1.2.3-65-gdbad