From 391a95f66f3199a4e9d07c8ce46330cebc356acd Mon Sep 17 00:00:00 2001
From: Aisha Tammy <floss@bsd.ac>
Date: Sun, 18 Apr 2021 16:17:31 -0400
Subject: gui-apps/waypipe: version bump to 0.8.0

Closes: https://bugs.gentoo.org/782757

Package-Manager: Portage-3.0.18, Repoman-3.0.3
Signed-off-by: Aisha Tammy <gentoo@aisha.cc>
Closes: https://github.com/gentoo/gentoo/pull/19728
Signed-off-by: Joonas Niilola <juippis@gentoo.org>
---
 gui-apps/waypipe/Manifest             |  1 +
 gui-apps/waypipe/waypipe-0.8.0.ebuild | 73 +++++++++++++++++++++++++++++++++++
 2 files changed, 74 insertions(+)
 create mode 100644 gui-apps/waypipe/waypipe-0.8.0.ebuild

diff --git a/gui-apps/waypipe/Manifest b/gui-apps/waypipe/Manifest
index 50c4b956b8a0..d226736c8ada 100644
--- a/gui-apps/waypipe/Manifest
+++ b/gui-apps/waypipe/Manifest
@@ -1 +1,2 @@
 DIST waypipe-0.7.2.tar.gz 202601 BLAKE2B bc8a03c8b47ee65a158ca45047f1989761c36b7b6fb5196784637f4e937fa2e5076497079f8368daf20592351e60a12fda5f4500b7220320b4c4a73ca9e5b1e0 SHA512 b126ea9d30864ecba67447793f39dbbe8bc73ab33c79879ac243023c64930e9aae887f13c0fdcc4cdf307b0ca6766b1012915dc88c596b7c250e3b35f6ba9190
+DIST waypipe-0.8.0.tar.gz 217533 BLAKE2B a2aebb9939acafae3eb693aa8fe344ab775e8d3e9a071e7291ab15a0f9869b681156b5730e42c04401648a32ad2a67d7a3bf95ff5f38e909e9309e00b1c69381 SHA512 853d36a9779e2fcb5ac7bcca6575d456685beadd8d918ec430a57b8359867849bdcb5d9c1edcd19eb8505f06a7758e8f53ba5354daa05f99491d5a45c330eeb2
diff --git a/gui-apps/waypipe/waypipe-0.8.0.ebuild b/gui-apps/waypipe/waypipe-0.8.0.ebuild
new file mode 100644
index 000000000000..a105c5722610
--- /dev/null
+++ b/gui-apps/waypipe/waypipe-0.8.0.ebuild
@@ -0,0 +1,73 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit meson python-any-r1
+
+DESCRIPTION="Transparent network proxy for Wayland compositors"
+HOMEPAGE="https://gitlab.freedesktop.org/mstoeckl/waypipe"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.freedesktop.org/mstoeckl/waypipe"
+else
+	SRC_URI="https://gitlab.freedesktop.org/mstoeckl/waypipe/-/archive/v${PV}/${PN}-v${PV}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}"/${PN}-v${PV}
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+
+WAYPIPE_FLAG_MAP_X86=( avx2:with_avx2 avx512f:with_avx512f sse3:with_sse3 )
+WAYPIPE_FLAG_MAP_ARM=( neon:with_neon_opts )
+WAYPIPE_FLAG_MAP=(
+	"${WAYPIPE_FLAG_MAP_X86[@]/#/cpu_flags_x86_}"
+	"${WAYPIPE_FLAG_MAP_ARM[@]/#/cpu_flags_arm_}"
+)
+
+IUSE="dmabuf ffmpeg lz4 man neon systemtap test vaapi zstd ${WAYPIPE_FLAG_MAP[@]%:*}"
+REQUIRED_USE="vaapi? ( ffmpeg )"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	dmabuf? (
+		media-libs/mesa[gbm,vaapi?,wayland]
+		x11-libs/libdrm
+	)
+	lz4? ( app-arch/lz4 )
+	systemtap? ( dev-util/systemtap )
+	vaapi? ( x11-libs/libva[drm,wayland] )
+	ffmpeg? (
+		media-video/ffmpeg[x264,vaapi?]
+	)
+	zstd? ( app-arch/zstd )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+	man? ( app-text/scdoc )
+	test? ( dev-libs/weston[examples,headless,remoting,screen-sharing,wayland-compositor] )
+"
+
+src_configure() {
+	local emesonargs=(
+		-Dwerror=false
+		$(meson_use systemtap with_systemtap)
+		$(meson_feature dmabuf with_dmabuf)
+		$(meson_feature ffmpeg with_video)
+		$(meson_feature lz4 with_lz4)
+		$(meson_feature man man-pages)
+		$(meson_feature vaapi with_vaapi)
+		$(meson_feature zstd with_zstd)
+	)
+	local fl
+	for fl in "${WAYPIPE_FLAG_MAP[@]}"; do
+		emesonargs+=( $(meson_use "${fl%:*}" "${fl#*:}") )
+	done
+	meson_src_configure
+}
-- 
cgit v1.2.3-65-gdbad