From 3e1964ed212d23e5bed06e51de4de9c2031b00f1 Mon Sep 17 00:00:00 2001
From: Michał Górny <mgorny@gentoo.org>
Date: Sun, 4 Jun 2023 07:28:37 +0200
Subject: dev-python/python-ctags3: Bump to 1.6.0
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/python-ctags3/Manifest                  |  1 +
 .../python-ctags3/python-ctags3-1.6.0.ebuild       | 47 ++++++++++++++++++++++
 2 files changed, 48 insertions(+)
 create mode 100644 dev-python/python-ctags3/python-ctags3-1.6.0.ebuild

diff --git a/dev-python/python-ctags3/Manifest b/dev-python/python-ctags3/Manifest
index cb0a9f4390f9..f15cc365e95b 100644
--- a/dev-python/python-ctags3/Manifest
+++ b/dev-python/python-ctags3/Manifest
@@ -1 +1,2 @@
 DIST python-ctags3-1.5.0.gh.tar.gz 63921 BLAKE2B 1d25e7bafbdf157f1051321058b39fc9347bc479a61fae637bd11ef8540a3c67e2abd101493668977f05e464a8203b8c518fd1f4433defe5cec9939a200438b2 SHA512 414774c865af51e54c53f66dc7b3cfb5a03b64ea4eb94325658c158542615dfffdd1a5933d9ae03cedf1dbac30e1810d5914fbc3d6ab41e5f708c5d3000d161e
+DIST python-ctags3-1.6.0.gh.tar.gz 70311 BLAKE2B f286aad922f8220d5f0b42f2919425d836bd27e9b2a85739333295d6e681172b20d33d010821c881583a4bed29d103939cf4b7e1d67190ba52cf1e0a1ca75290 SHA512 38df28c1055b2240e5da7699a7c72bab85908c7b1a1b4db83f19350541fe49d8499a9b7400ad14c77166b459fbb30f6b2c22d65685ac5f392ececa3eeecb6f41
diff --git a/dev-python/python-ctags3/python-ctags3-1.6.0.ebuild b/dev-python/python-ctags3/python-ctags3-1.6.0.ebuild
new file mode 100644
index 000000000000..89f53b3750e2
--- /dev/null
+++ b/dev-python/python-ctags3/python-ctags3-1.6.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{10..12} )
+
+inherit distutils-r1
+
+MY_P="python-ctags3-${PV}"
+DESCRIPTION="Exuberant Ctags indexing python bindings"
+HOMEPAGE="https://github.com/universal-ctags/python-ctags3"
+# PyPI tarballs don't contain pyx files
+SRC_URI="https://github.com/universal-ctags/python-ctags3/archive/${PV}.tar.gz -> ${MY_P}.gh.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="
+	dev-util/ctags:=
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# We currently need to let Cython regenerate this file to make Python 3.11
+	# support work
+	rm src/_readtags.c || die
+	cython -3 src/_readtags.pyx || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# To prevent pytest from importing it and failing with:
+	# ModuleNotFoundError: No module named 'ctags._readtags'
+	rm -rf src/ctags || die
+	epytest
+}
-- 
cgit v1.2.3-65-gdbad