From 464d1ab3324d3d5a208fe04b6d5bde5855155e8a Mon Sep 17 00:00:00 2001
From: Matt Turner <mattst88@gentoo.org>
Date: Sat, 4 Jun 2022 13:35:49 -0400
Subject: dev-libs/gmime: Version bump to 3.2.12

Closes: https://bugs.gentoo.org/811963
Signed-off-by: Matt Turner <mattst88@gentoo.org>
---
 dev-libs/gmime/Manifest            |  1 +
 dev-libs/gmime/gmime-3.2.12.ebuild | 69 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 70 insertions(+)
 create mode 100644 dev-libs/gmime/gmime-3.2.12.ebuild

diff --git a/dev-libs/gmime/Manifest b/dev-libs/gmime/Manifest
index 6d1d542c0fa7..854646792ebe 100644
--- a/dev-libs/gmime/Manifest
+++ b/dev-libs/gmime/Manifest
@@ -1,2 +1,3 @@
 DIST gmime-2.6.23.tar.xz 5216588 BLAKE2B e173a7dbd418663ebbc55b856359bf9286c3791827f9b7f89da48dd7c3609e77312546f9489c08d34a7dcaeb78659789809d5fafc1323cbae9b9f1c4a316c659 SHA512 2ff6718b7a555cd5b34848399f29c7d0aa5a15e1f3cb46e9258c499e874191ee00f41b737386805d3000bad34367d174a25c45d38ba90cba7902400e733afa14
 DIST gmime-3.2.11.tar.xz 2230984 BLAKE2B 7a1758d8b7b3e4a3b27819b3cd4002247209b0d979813b3071d7423341c0a5786d929110c18d23bad5fb74cb15a142382eb63afc1bc019b1da148ed8a0acd524 SHA512 0d61ce2c7716de3fec2b6666937f01b880b45a1fe7b6c40b5d253e8510f8a4af3b274473b0da4319018747484df35df7ac8fe0ebae019b2f956c525182cf30f8
+DIST gmime-3.2.12.tar.xz 2233844 BLAKE2B 863a0634586a478faf32a201051639c33c214d0acb2b7852ba82a3be1f923ad44f3d04390bd9b62991ebaa17da19b6f74f4ce334ff8272563750587793256164 SHA512 2b2529d36bac4501cc79f9b8127a9f0898fce9ce91dbf8a6c72037d120a2fbccbb97b91b00b81fed15bae4232c59700efacf1c94910a06c66340e67815df5afb
diff --git a/dev-libs/gmime/gmime-3.2.12.ebuild b/dev-libs/gmime/gmime-3.2.12.ebuild
new file mode 100644
index 000000000000..a7eed9e822c8
--- /dev/null
+++ b/dev-libs/gmime/gmime-3.2.12.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic gnome2 vala
+
+DESCRIPTION="Library for creating and parsing MIME messages"
+HOMEPAGE="https://github.com/jstedfast/gmime http://spruce.sourceforge.net/gmime/"
+SRC_URI="https://github.com/jstedfast/${PN}/releases/download/${PV}/${P}.tar.xz"
+
+SLOT="3.0"
+LICENSE="LGPL-2.1+"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris ~x86-solaris"
+IUSE="crypt doc idn test +vala"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/glib-2.58.0:2
+	sys-libs/zlib
+	crypt? ( >=app-crypt/gpgme-1.8.0:= )
+	idn? ( net-dns/libidn2:= )
+	vala? (
+		$(vala_depend)
+		>=dev-libs/gobject-introspection-1.30.0:= )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.8
+	virtual/libiconv
+	virtual/pkgconfig
+	doc? ( app-text/docbook-sgml-utils )
+	test? ( app-crypt/gnupg )
+"
+# gnupg is needed for tests if --enable-cryptography is enabled, which we do unconditionally
+
+src_prepare() {
+	gnome2_src_prepare
+	use vala && vala_setup
+}
+
+src_configure() {
+	if [[ ${CHOST} == *-solaris* ]]; then
+		# bug #???, why not use --with-libiconv
+		append-libs iconv
+	fi
+
+	gnome2_src_configure \
+		--enable-largefile \
+		$(use_enable crypt crypto) \
+		$(use_enable vala) \
+		$(use_with idn libidn) \
+		$(usex doc "" DB2HTML=)
+}
+
+src_compile() {
+	gnome2_src_compile
+	if use doc; then
+		emake -C docs/tutorial html
+	fi
+}
+
+src_install() {
+	gnome2_src_install
+
+	if use doc ; then
+		docinto tutorial
+		dodoc -r docs/tutorial/html/
+	fi
+}
-- 
cgit v1.2.3-65-gdbad