From 4a861e8d5d417499eff98220075310b52854c8bd Mon Sep 17 00:00:00 2001
From: Matt Turner <mattst88@gentoo.org>
Date: Mon, 12 Apr 2021 16:50:54 -0400
Subject: app-crypt/gcr: Version bump to 3.40.0

Signed-off-by: Matt Turner <mattst88@gentoo.org>
---
 app-crypt/gcr/Manifest          |  1 +
 app-crypt/gcr/gcr-3.40.0.ebuild | 83 +++++++++++++++++++++++++++++++++++++++++
 2 files changed, 84 insertions(+)
 create mode 100644 app-crypt/gcr/gcr-3.40.0.ebuild

diff --git a/app-crypt/gcr/Manifest b/app-crypt/gcr/Manifest
index 73db9ba79c65..f24045a67846 100644
--- a/app-crypt/gcr/Manifest
+++ b/app-crypt/gcr/Manifest
@@ -1,3 +1,4 @@
 DIST gcr-3.36.0.tar.xz 1025760 BLAKE2B 03f0d0ed40b600ed80e894111fedff3efcbbaaf6f261d6a44a3649a1acb50c4f35f3dc9a7ddb60f56cab241f68fef83aa5a02a94036e70a6556b35300f2c8fb5 SHA512 0431e7971b73accc62869c9497fcff7c111c453aa6a8ff25b42f19ceae1be0aec52e0e4eb504676f967c6e4f179198c15c521278690822e3457dbc5fe512fd5e
 DIST gcr-3.38.0.tar.xz 1029784 BLAKE2B cf295a9f497d6c54067717e806439166965f90670ed5f7283802bb70c547465d9cc28d452970269d4315d02d24cc31f483a0a1fc1807f9b9720e70aa2b8249b9 SHA512 24c35ac514a67a1dee6a5738e829b55921a490b060ffa597421cea0abac3ddc62695370d2c7b3504c0adfd55b1ade878ad3ca5e6cb869428b4a19f4a11563bc6
 DIST gcr-3.38.1.tar.xz 1030360 BLAKE2B 474b501a5f6c339b0b4fb460a094dec6d5a297ca44daf050c6c88bc05ee822358309f57490f92c42f84a1e9f36a1d3c09c4b2788d7142ee5e86e2acf7987ea14 SHA512 4dc8c3f84023a7cd6f069f4529cb063d7153e589c2f9547410c7eeb5298dc238ea7fc4f22e22d8c237391f31bfcd814190e55125195f20b913665b9ca81d9c21
+DIST gcr-3.40.0.tar.xz 1011044 BLAKE2B 6b1016f74e5fd3ace32a534a59575db9c39b5deefd2f4f3a747ef7e87a43c7c00b33500d8151009347af9fe6b073c390895bb6e17c577c6e150c780c487b997e SHA512 7118608e7bef7d0cf2eea33cb3286b7f9c3622a38892ce88cf33ed453d343cc33e070831e7b4d0c5cdb43c2e57b3f0b91c7cbd6aa8463982d3af8844b59bcb81
diff --git a/app-crypt/gcr/gcr-3.40.0.ebuild b/app-crypt/gcr/gcr-3.40.0.ebuild
new file mode 100644
index 000000000000..1cc41b03fc6d
--- /dev/null
+++ b/app-crypt/gcr/gcr-3.40.0.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+VALA_USE_DEPEND="vapigen"
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit gnome.org gnome2-utils meson python-any-r1 vala xdg
+
+DESCRIPTION="Libraries for cryptographic UIs and accessing PKCS#11 modules"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gcr"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0/1" # subslot = suffix of libgcr-base-3 and co
+
+IUSE="gtk gtk-doc +introspection test +vala"
+REQUIRED_USE="vala? ( introspection )"
+RESTRICT="!test? ( test )"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~sparc-solaris ~x86-solaris"
+
+DEPEND="
+	>=dev-libs/glib-2.44.0:2
+	>=dev-libs/libgcrypt-1.2.2:0=
+	>=app-crypt/p11-kit-0.19.0
+	gtk? ( >=x11-libs/gtk+-3.22:3[introspection?] )
+	>=sys-apps/dbus-1
+	introspection? ( >=dev-libs/gobject-introspection-1.58:= )
+"
+RDEPEND="${DEPEND}"
+PDEPEND="app-crypt/gnupg"
+BDEPEND="
+	${PYTHON_DEPS}
+	gtk? ( dev-libs/libxml2:2 )
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	gtk-doc? (
+		>=dev-util/gtk-doc-1.9
+		app-text/docbook-xml-dtd:4.1.2
+	)
+	>=sys-devel/gettext-0.19.8
+	test? ( app-crypt/gnupg )
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+
+PATCHES=(
+	"${FILESDIR}"/3.38.0-optional-vapi.patch
+)
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	use vala && vala_src_prepare
+	xdg_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use introspection)
+		$(meson_use gtk)
+		$(meson_use gtk-doc gtk_doc)
+		-Dgpg_path="${EPREFIX}"/usr/bin/gpg
+		$(meson_use vala vapi)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	dbus-run-session meson test -C "${BUILD_DIR}" || die 'tests failed'
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}
-- 
cgit v1.2.3-65-gdbad