From 505f55b4d7a21dca4356133cb57b51b80097a1c3 Mon Sep 17 00:00:00 2001
From: Michał Górny <mgorny@gentoo.org>
Date: Thu, 8 Feb 2024 15:44:47 +0100
Subject: dev-python/hatchling: Remove old
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/hatchling/Manifest                |  1 -
 dev-python/hatchling/hatchling-1.21.0.ebuild | 86 ----------------------------
 2 files changed, 87 deletions(-)
 delete mode 100644 dev-python/hatchling/hatchling-1.21.0.ebuild

diff --git a/dev-python/hatchling/Manifest b/dev-python/hatchling/Manifest
index 59895a6ba09e..e649befe087c 100644
--- a/dev-python/hatchling/Manifest
+++ b/dev-python/hatchling/Manifest
@@ -1,2 +1 @@
-DIST hatch-hatchling-v1.21.0.gh.tar.gz 764748 BLAKE2B 3b048ed34df4da9ed5ec8d1c0121e21aabada559e981e9fd36a7188aceedf79594b165ed705edfbc5d210a09ee9a022c8c6e433e930338f2053e4c48feef0d44 SHA512 5ee8151929d6bdbb67e7f4e3e0298c730ff7fef5a7d7b764192eb2e16327d80a2935eee8831c168d19ed41c7184ca5b5eef7a67c9d5756cea25a7bd79945d344
 DIST hatch-hatchling-v1.21.1.gh.tar.gz 774577 BLAKE2B 31e2b50598b4fe120ecea407a37e3262876a2ec1e8cf02f272c25838e73afc37f2fef1f8fab08b2e3b83bfd828f6c558ce303b084081b83504343a8bb057c341 SHA512 91b5684737fac19758d7095b357f99031d46e9f981e093cab848ce770fd1f9440b69212f3ef2217e3700e7dd7985a97c2735bbd27b306c7b8aa7bffc5c950fb4
diff --git a/dev-python/hatchling/hatchling-1.21.0.ebuild b/dev-python/hatchling/hatchling-1.21.0.ebuild
deleted file mode 100644
index 9233bcc8808f..000000000000
--- a/dev-python/hatchling/hatchling-1.21.0.ebuild
+++ /dev/null
@@ -1,86 +0,0 @@
-# Copyright 2022-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=standalone
-PYTHON_TESTED=( pypy3 python3_{10..12} )
-PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
-
-inherit distutils-r1
-
-TAG=${P/-/-v}
-MY_P=hatch-${TAG}
-DESCRIPTION="Modern, extensible Python build backend"
-HOMEPAGE="
-	https://pypi.org/project/hatchling/
-	https://github.com/pypa/hatch/
-"
-SRC_URI="
-	https://github.com/pypa/hatch/archive/${TAG}.tar.gz
-		-> ${MY_P}.gh.tar.gz
-"
-S=${WORKDIR}/${MY_P}/backend
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
-
-# deps are listed in backend/src/hatchling/ouroboros.py
-RDEPEND="
-	>=dev-python/editables-0.3[${PYTHON_USEDEP}]
-	>=dev-python/packaging-21.3[${PYTHON_USEDEP}]
-	>=dev-python/pathspec-0.10.1[${PYTHON_USEDEP}]
-	>=dev-python/pluggy-1.0.0[${PYTHON_USEDEP}]
-	$(python_gen_cond_dep '
-		>=dev-python/tomli-1.2.2[${PYTHON_USEDEP}]
-	' 3.10)
-	dev-python/trove-classifiers[${PYTHON_USEDEP}]
-"
-BDEPEND="
-	${RDEPEND}
-	test? (
-		$(python_gen_cond_dep '
-			dev-python/atomicwrites[${PYTHON_USEDEP}]
-			dev-python/click[${PYTHON_USEDEP}]
-			dev-python/httpx[${PYTHON_USEDEP}]
-			dev-python/platformdirs[${PYTHON_USEDEP}]
-			dev-python/pytest-mock[${PYTHON_USEDEP}]
-			dev-python/rich[${PYTHON_USEDEP}]
-			dev-python/tomli-w[${PYTHON_USEDEP}]
-			dev-python/virtualenv[${PYTHON_USEDEP}]
-		' "${PYTHON_TESTED[@]}")
-	)
-"
-
-distutils_enable_tests pytest
-
-python_test() {
-	if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
-		einfo "Skipping tests on ${EPYTHON}"
-		return
-	fi
-
-	local -x EPYTEST_DESELECT=(
-		# these run pip to install stuff
-		tests/backend/dep/test_core.py::test_dependency_found
-		tests/backend/dep/test_core.py::test_extra_met
-		tests/backend/dep/test_core.py::test_extra_no_dependencies
-		tests/backend/dep/test_core.py::test_extra_unmet
-		tests/backend/dep/test_core.py::test_unknown_extra
-		tests/backend/dep/test_core.py::test_version_unmet
-		# broken if CARGO is set
-		tests/backend/builders/test_app.py::TestBuildBootstrap::test_no_cargo
-	)
-
-	# top-level "tests" directory contains tests both for hatch
-	# and hatchling
-	cd "${WORKDIR}/${MY_P}" || die
-	local -x PYTHONPATH="src:${PYTHONPATH}"
-	# sigh; standalone test suites are overrated, right?
-	echo "__version__ = '${PV}'" > src/hatch/_version.py || die
-	# tests mock cargo subprocess call but the backend raises if CARGO
-	# is not set and shutil.which() can't find it
-	local -x CARGO=cargo
-	epytest tests/backend
-}
-- 
cgit v1.2.3-65-gdbad