From 5093dba354323dd219e58be5e7f9a779c9bae8c6 Mon Sep 17 00:00:00 2001
From: Louis Sautier <sbraz@gentoo.org>
Date: Tue, 31 Dec 2019 15:08:49 +0100
Subject: dev-python/irc: bump to 18.0.0, drops <Py3.6, add Py3.8

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Louis Sautier <sbraz@gentoo.org>
---
 dev-python/irc/Manifest          |  1 +
 dev-python/irc/irc-18.0.0.ebuild | 69 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 70 insertions(+)
 create mode 100644 dev-python/irc/irc-18.0.0.ebuild

diff --git a/dev-python/irc/Manifest b/dev-python/irc/Manifest
index cb4335555894..f157d95fd9e4 100644
--- a/dev-python/irc/Manifest
+++ b/dev-python/irc/Manifest
@@ -1,3 +1,4 @@
 DIST irc-16.3.tar.gz 87067 BLAKE2B 61d8b9cc20390a3eb918e5593a167b28f37154ee05cb4d7a72f8901509d3345e8d6bee9c17b66aa6c71fad4608a9f98eb3848190f82eac7db6f2013227979c25 SHA512 84b5a56a441cdf22396c10b81c115cb2e297ac082785e9baf0bc73d655034be1ff3f553d44412f066ab4b74530faddb66a9cc2f511a332e87fe49af0b6e68e5b
 DIST irc-17.0.tar.gz 86522 BLAKE2B 1fc1d2faa4e13bfdabffbccae0c40ea7dd477894a5b6f24370950d4bce5e833103fcd2c20d39e2fd0490975b1f36fb234bc354d08f1524062f4dfe7195158750 SHA512 7afef790048b6905d1ae1fa559fa100f57a508586a9d3641890c578730677c965b5c1dc9e00927c8178955632ff919c00484c535eaaaa5c411ce15f68a7d3f93
 DIST irc-17.1.tar.gz 90266 BLAKE2B bcee4710527d718c43fd836f36c48af4bd3b92aee202b0197be710ffc249b3b24d6bfb4f092a102ba0789325e0322b23d65af3fd5d7aa45cf0174d278b5d5282 SHA512 8c6a7d1e302ddfdb86808fe422f922a4bf088dd2890e5ca7a924ca960e603c78e9aedab202c895c555e3ad569e6be133aff652e0a374a16e3ab165100e6fecb6
+DIST irc-18.0.0.tar.gz 91529 BLAKE2B 91e7f9fe38b46f836eb902c8ce4ca04706e673a8a9372c743e9b6be3b400e4d84a0d841b72e2b8444e055a69d37b22d48fcf33c7bd51375dbf0dd4a06b3ed5dd SHA512 a424f1261a09246dd2cfd0b717d4fd9bbeab9754d1f480c870c2e131354db85268bd010ec6b7cf2c59a0c32057bb290ef3ffdcb30cca8c0d833e1497bc89f58e
diff --git a/dev-python/irc/irc-18.0.0.ebuild b/dev-python/irc/irc-18.0.0.ebuild
new file mode 100644
index 000000000000..5b30887f153f
--- /dev/null
+++ b/dev-python/irc/irc-18.0.0.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit distutils-r1
+
+DESCRIPTION="IRC client framework written in Python"
+HOMEPAGE="https://github.com/jaraco/irc"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	$(python_gen_cond_dep 'dev-python/importlib_metadata[${PYTHON_USEDEP}]' python3_{6,7})
+	dev-python/jaraco-collections[${PYTHON_USEDEP}]
+	>=dev-python/jaraco-functools-1.20[${PYTHON_USEDEP}]
+	>=dev-python/jaraco-itertools-1.8[${PYTHON_USEDEP}]
+	dev-python/jaraco-logging[${PYTHON_USEDEP}]
+	dev-python/jaraco-stream[${PYTHON_USEDEP}]
+	dev-python/jaraco-text[${PYTHON_USEDEP}]
+	dev-python/more-itertools[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	>=dev-python/tempora-1.6[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/setuptools_scm-1.15.0[${PYTHON_USEDEP}]
+	doc? (
+		>=dev-python/jaraco-packaging-3.2[${PYTHON_USEDEP}]
+		>=dev-python/rst-linker-1.9[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+	test? (
+		${RDEPEND}
+		dev-python/backports-unittest-mock[${PYTHON_USEDEP}]
+		>=dev-python/pytest-2.8[${PYTHON_USEDEP}]
+	)
+"
+
+python_compile_all() {
+	if use doc; then
+		# conf.py looks for '../CHANGES.rst'
+		cd docs || die
+		sphinx-build . _build/html || die
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	# Override pytest options to skip flake8
+	# Skip a test that fails with 3.8 until it is fixed
+	# https://github.com/jaraco/irc/issues/165
+	pytest -vv --override-ini="addopts=--doctest-modules" \
+		--deselect irc/tests/test_client_aio.py::test_privmsg_sends_msg \
+		|| die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/scripts"
+		dodoc -r scripts
+	fi
+	distutils-r1_python_install_all
+}
-- 
cgit v1.2.3-65-gdbad