From 536705035512808ac19addaf703e23bb55adfc71 Mon Sep 17 00:00:00 2001
From: Ionen Wolkens <ionen@gentoo.org>
Date: Tue, 11 Oct 2022 06:29:12 -0400
Subject: dev-util/cutils: EAPI7->8, fix direct AR and build w/ clang16

Closes: https://bugs.gentoo.org/724270
Closes: https://bugs.gentoo.org/871402
Signed-off-by: Ionen Wolkens <ionen@gentoo.org>
---
 dev-util/cutils/cutils-1.6-r4.ebuild           | 56 ----------------------
 dev-util/cutils/cutils-1.6-r5.ebuild           | 64 ++++++++++++++++++++++++++
 dev-util/cutils/files/cutils-1.6-ar.patch      |  8 ++++
 dev-util/cutils/files/cutils-1.6-clang16.patch | 19 ++++++++
 4 files changed, 91 insertions(+), 56 deletions(-)
 delete mode 100644 dev-util/cutils/cutils-1.6-r4.ebuild
 create mode 100644 dev-util/cutils/cutils-1.6-r5.ebuild
 create mode 100644 dev-util/cutils/files/cutils-1.6-ar.patch
 create mode 100644 dev-util/cutils/files/cutils-1.6-clang16.patch

diff --git a/dev-util/cutils/cutils-1.6-r4.ebuild b/dev-util/cutils/cutils-1.6-r4.ebuild
deleted file mode 100644
index a7b7e983a7b2..000000000000
--- a/dev-util/cutils/cutils-1.6-r4.ebuild
+++ /dev/null
@@ -1,56 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit toolchain-funcs
-
-DESCRIPTION="C language utilities"
-HOMEPAGE="http://www.sigala.it/sandro/software.php#cutils"
-SRC_URI="http://www.sigala.it/sandro/files/${P}.tar.gz"
-
-LICENSE="BSD-2"
-SLOT="0"
-KEYWORDS="amd64 ppc x86 ~amd64-linux ~x86-linux ~ppc-macos"
-
-BDEPEND="sys-devel/flex"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-infopage.patch
-	"${FILESDIR}"/${P}-case-insensitive.patch
-)
-
-src_prepare() {
-	default
-
-	mv src/cdecl/{,cutils-}cdecl.1 || die
-
-	# delete pointless README
-	rm README.compile || die
-
-	# Force rebuild of cutils.info
-	rm doc/cutils.info || die
-
-	sed -e "s/cdecl/cutils-cdecl/g"	\
-		-i doc/cutils.texi || die
-	sed -e "/PROG/s/cdecl/cutils-cdecl/" \
-		-i src/cdecl/Makefile.in || die
-	sed -e "/Xr/s/cdecl/cutils-cdecl/" \
-		-i src/cundecl/cundecl.1 || die
-	sed -e "/Nm/s/cdecl/cutils-cdecl/" \
-		-i src/cdecl/cutils-cdecl.1 || die
-}
-
-src_compile() {
-	emake CC="$(tc-getCC)" -j1
-}
-
-src_install() {
-	default
-	dodoc HISTORY
-}
-
-pkg_postinst() {
-	elog "cdecl was installed as cutils-cdecl because of a naming conflict"
-	elog "with dev-util/cdecl."
-}
diff --git a/dev-util/cutils/cutils-1.6-r5.ebuild b/dev-util/cutils/cutils-1.6-r5.ebuild
new file mode 100644
index 000000000000..8f45dcfd811b
--- /dev/null
+++ b/dev-util/cutils/cutils-1.6-r5.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools toolchain-funcs
+
+DESCRIPTION="C language utilities"
+HOMEPAGE="http://www.sigala.it/sandro/software.php#cutils"
+SRC_URI="http://www.sigala.it/sandro/files/${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="amd64 ppc x86 ~amd64-linux ~x86-linux ~ppc-macos"
+
+BDEPEND="
+	sys-devel/flex
+	virtual/yacc"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-infopage.patch
+	"${FILESDIR}"/${P}-case-insensitive.patch
+	"${FILESDIR}"/${P}-ar.patch
+	"${FILESDIR}"/${P}-clang16.patch
+)
+
+src_prepare() {
+	default
+
+	mv src/cdecl/{,cutils-}cdecl.1 || die
+
+	# delete pointless README
+	rm README.compile || die
+
+	# Force rebuild of cutils.info
+	rm doc/cutils.info || die
+
+	sed -e "s/cdecl/cutils-cdecl/g"	\
+		-i doc/cutils.texi || die
+	sed -e "/PROG/s/cdecl/cutils-cdecl/" \
+		-i src/cdecl/Makefile.in || die
+	sed -e "/Xr/s/cdecl/cutils-cdecl/" \
+		-i src/cundecl/cundecl.1 || die
+	sed -e "/Nm/s/cdecl/cutils-cdecl/" \
+		-i src/cdecl/cutils-cdecl.1 || die
+
+	eautoreconf #871402
+}
+
+src_compile() {
+	tc-export AR #724270
+
+	emake -j1
+}
+
+src_install() {
+	default
+	dodoc HISTORY
+}
+
+pkg_postinst() {
+	elog "cdecl was installed as cutils-cdecl because of a naming conflict"
+	elog "with dev-util/cdecl."
+}
diff --git a/dev-util/cutils/files/cutils-1.6-ar.patch b/dev-util/cutils/files/cutils-1.6-ar.patch
new file mode 100644
index 000000000000..68a3372e3b01
--- /dev/null
+++ b/dev-util/cutils/files/cutils-1.6-ar.patch
@@ -0,0 +1,8 @@
+https://bugs.gentoo.org/724270
+--- a/lib/Makefile.in
++++ b/lib/Makefile.in
+@@ -21,3 +21,3 @@
+ 	rm -f $(LIB)
+-	ar rc $(LIB) $(OBJS)
++	$(AR) rc $(LIB) $(OBJS)
+ 	$(RANLIB) $(LIB)
diff --git a/dev-util/cutils/files/cutils-1.6-clang16.patch b/dev-util/cutils/files/cutils-1.6-clang16.patch
new file mode 100644
index 000000000000..3c40b4ccf3c0
--- /dev/null
+++ b/dev-util/cutils/files/cutils-1.6-clang16.patch
@@ -0,0 +1,19 @@
+https://bugs.gentoo.org/871402
+--- a/src/cdecl/parser.y
++++ b/src/cdecl/parser.y
+@@ -46,2 +46,3 @@
+ extern FILE *output_file;
++extern int yylex(void);
+ 
+--- a/src/cundecl/parser.y
++++ b/src/cundecl/parser.y
+@@ -47,2 +47,3 @@
+ extern FILE *output_file;
++extern int yylex(void);
+ 
+--- a/src/yyref/parser.y
++++ b/src/yyref/parser.y
+@@ -50,2 +50,3 @@
+ extern int lineno;
++extern int yylex(void);
+ 
-- 
cgit v1.2.3-65-gdbad