From 6118f3f56f85c66dbd4cf3eb5ad9e08065d33766 Mon Sep 17 00:00:00 2001
From: Michał Górny <mgorny@gentoo.org>
Date: Tue, 5 Sep 2023 07:37:00 +0200
Subject: dev-python/ipykernel: Bump to 6.25.2
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/ipykernel/Manifest                |  1 +
 dev-python/ipykernel/ipykernel-6.25.2.ebuild | 79 ++++++++++++++++++++++++++++
 2 files changed, 80 insertions(+)
 create mode 100644 dev-python/ipykernel/ipykernel-6.25.2.ebuild

diff --git a/dev-python/ipykernel/Manifest b/dev-python/ipykernel/Manifest
index 691000c3ed4f..130a9dbf0a08 100644
--- a/dev-python/ipykernel/Manifest
+++ b/dev-python/ipykernel/Manifest
@@ -1 +1,2 @@
 DIST ipykernel-6.25.1.tar.gz 155925 BLAKE2B 973ee4b674ccc83adbff302cd967573fde17e20067366d32daba7f95db6f9ba3312d7418b8800222a2eb73b7061c65cea366ab1cdbc25e74fdbefbe50546cfc5 SHA512 501aa98a50b677037f9d81415bc56b50a1b7b056c25d6edd1eb116eed6c0fe41cff067bf88535880cdae0749eb569ba428c9389a22c77b54c2deea8f2eebf99b
+DIST ipykernel-6.25.2.tar.gz 156247 BLAKE2B 796ed40dd5ef11dbe8a0bb330aafd1e51e40b1fa5a0b55bdb1a1aff4d89187b3c6b3831f3d44b131f5e8158d6035697f788877a8e682c4c0355da74825ee2200 SHA512 a6f5089cff8c297379ae840b49ad705d23db46aa04030c7a2598031d118b5c0dd64e091de4d66adfd876e8ef45abfcb6bc963c3311dd8e50f4e83236bfc4cfa3
diff --git a/dev-python/ipykernel/ipykernel-6.25.2.ebuild b/dev-python/ipykernel/ipykernel-6.25.2.ebuild
new file mode 100644
index 000000000000..bac003cd898d
--- /dev/null
+++ b/dev-python/ipykernel/ipykernel-6.25.2.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{10..11} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 pypi virtualx
+
+DESCRIPTION="IPython Kernel for Jupyter"
+HOMEPAGE="
+	https://github.com/ipython/ipykernel/
+	https://pypi.org/project/ipykernel/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos"
+
+RDEPEND="
+	>=dev-python/comm-0.1.1[${PYTHON_USEDEP}]
+	!elibc_Darwin? ( >=dev-python/debugpy-1.6.5[${PYTHON_USEDEP}] )
+	>=dev-python/ipython-7.23.1[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-client-8[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-core-4.12[${PYTHON_USEDEP}]
+	>=dev-python/matplotlib-inline-0.1[${PYTHON_USEDEP}]
+	dev-python/nest-asyncio[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/psutil[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-20[${PYTHON_USEDEP}]
+	>=dev-python/tornado-6.1[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.4.0[${PYTHON_USEDEP}]
+"
+# RDEPEND seems specifically needed in BDEPEND, at least jupyter
+# bug #816486
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		dev-python/ipyparallel[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i -e 's:^TIMEOUT = .*:TIMEOUT = 120:' ipykernel/tests/*.py || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	# Use python3 in kernel.json configuration, bug #784764
+	sed -i -e '/python3.[0-9]\+/s//python3/' \
+		"${BUILD_DIR}/install${EPREFIX}/usr/share/jupyter/kernels/python3/kernel.json" || die
+}
+
+src_test() {
+	local EPYTEST_DESELECT=(
+		# TODO
+		ipykernel/tests/test_debugger.py::test_attach_debug
+		ipykernel/tests/test_debugger.py::test_breakpoint_in_cell_with_leading_empty_lines
+		ipykernel/tests/test_debugger.py::test_rich_inspect_at_breakpoint
+		ipykernel/tests/test_debugger.py::test_rich_inspect_not_at_breakpoint
+		ipykernel/tests/test_debugger.py::test_set_breakpoints
+		ipykernel/tests/test_debugger.py::test_stop_on_breakpoint
+		ipykernel/tests/test_debugger.py::test_copy_to_globals
+		# hangs?
+		ipykernel/tests/test_eventloop.py::test_tk_loop
+		# doesn't like pyside2?
+		ipykernel/tests/test_eventloop.py::test_qt_enable_gui
+	)
+
+	virtx distutils-r1_src_test
+}
-- 
cgit v1.2.3-65-gdbad