From 64103682c0b482b8ee18ea4cf59707d272a6f5ef Mon Sep 17 00:00:00 2001
From: Michał Górny <mgorny@gentoo.org>
Date: Thu, 1 Nov 2018 08:48:44 +0100
Subject: dev-cpp/libjson-rpc-cpp: Bump to 1.1.1
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-cpp/libjson-rpc-cpp/Manifest                   |  1 +
 .../libjson-rpc-cpp/libjson-rpc-cpp-1.1.1.ebuild   | 67 ++++++++++++++++++++++
 2 files changed, 68 insertions(+)
 create mode 100644 dev-cpp/libjson-rpc-cpp/libjson-rpc-cpp-1.1.1.ebuild

diff --git a/dev-cpp/libjson-rpc-cpp/Manifest b/dev-cpp/libjson-rpc-cpp/Manifest
index 35423b5d5a07..fbffd6b0c0e2 100644
--- a/dev-cpp/libjson-rpc-cpp/Manifest
+++ b/dev-cpp/libjson-rpc-cpp/Manifest
@@ -1 +1,2 @@
 DIST libjson-rpc-cpp-1.1.0.tar.gz 179442 BLAKE2B cfbfe703d1a3d4ccaf6d4d475a7c1686c8f7afc28b025d6fd3bfebdc41cff2b944e6600e68073c1b7e7c0a2463cbf6e9724cf618c5d481bf7a4600019b529922 SHA512 bf34eedb196b1e214292976036a00e933f8a9b4325441ea2e4ae049a7c818014a68dd9d2f22d01588f5e6d1e9f465c73a133b0fd8282f8cf78a05a493f4c461b
+DIST libjson-rpc-cpp-1.1.1.tar.gz 179249 BLAKE2B bd8b737f76bceaa1be73d89a1f75472d8eae6f3da57a4da5a5a9eee2a52ba06034bcb4404e6b65368f6be1967c1a8b40f71e3bfbaa58f65b0ac8dced1b3f43af SHA512 64043aee3227262da41b56f6d53e4f8f9a56d3a43b695200020b47fb7eb6e121cf086b6e121c0eccecf381be90d77910d0f4371254d147f33310af4584a7d433
diff --git a/dev-cpp/libjson-rpc-cpp/libjson-rpc-cpp-1.1.1.ebuild b/dev-cpp/libjson-rpc-cpp/libjson-rpc-cpp-1.1.1.ebuild
new file mode 100644
index 000000000000..73b204623f7b
--- /dev/null
+++ b/dev-cpp/libjson-rpc-cpp/libjson-rpc-cpp-1.1.1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils
+
+DESCRIPTION="JSON-RPC (1.0 & 2.0) framework for C++"
+HOMEPAGE="https://github.com/cinemast/libjson-rpc-cpp"
+SRC_URI="https://github.com/cinemast/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0/1"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc +http-client +http-server redis-client redis-server +stubgen test"
+
+RDEPEND="
+	dev-libs/jsoncpp:=
+	http-client? ( net-misc/curl:= )
+	http-server? ( net-libs/libmicrohttpd:= )
+	redis-client? ( dev-libs/hiredis:= )
+	redis-server? ( dev-libs/hiredis:= )
+	stubgen? ( dev-libs/argtable:= )"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )
+	test? ( dev-cpp/catch )"
+
+RESTRICT="!test? ( test )"
+
+src_configure() {
+	local mycmakeargs=(
+		-DHTTP_CLIENT=$(usex http-client)
+		-DHTTP_SERVER=$(usex http-server)
+		-DREDIS_CLIENT=$(usex redis-client)
+		-DREDIS_SERVER=$(usex redis-server)
+		# they have no deps
+		-DTCP_SOCKET_CLIENT=ON
+		-DTCP_SOCKET_SERVER=ON
+		-DUNIX_DOMAIN_SOCKET_CLIENT=ON
+		-DUNIX_DOMAIN_SOCKET_SERVER=ON
+		# they are not installed
+		-DCOMPILE_EXAMPLES=OFF
+		-DCOMPILE_STUBGEN=$(usex stubgen)
+		-DCOMPILE_TESTS=$(usex test)
+		-DCATCH_INCLUDE_DIR="${EPREFIX}/usr/include/catch"
+	)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+
+	use doc && emake -C "${BUILD_DIR}" doc
+}
+
+src_test() {
+	# Tests fail randomly when run in parallel
+	local MAKEOPTS=-j1
+	cmake-utils_src_test
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	use doc && dodoc -r "${BUILD_DIR}"/doc/html
+}
-- 
cgit v1.2.3-65-gdbad