From 6819e0f6f299cde6cc6bcf2cc1d84101abe80c67 Mon Sep 17 00:00:00 2001
From: Craig Andrews <candrews@gentoo.org>
Date: Wed, 28 Apr 2021 17:37:22 -0400
Subject: app-arch/brotli: add USE="static-libs"

Closes: https://bugs.gentoo.org/786558
Package-Manager: Portage-3.0.18, Repoman-3.0.3
Signed-off-by: Craig Andrews <candrews@gentoo.org>
---
 app-arch/brotli/brotli-1.0.9-r2.ebuild | 85 ++++++++++++++++++++++++++++++++++
 app-arch/brotli/brotli-9999.ebuild     |  5 +-
 2 files changed, 88 insertions(+), 2 deletions(-)
 create mode 100644 app-arch/brotli/brotli-1.0.9-r2.ebuild

diff --git a/app-arch/brotli/brotli-1.0.9-r2.ebuild b/app-arch/brotli/brotli-1.0.9-r2.ebuild
new file mode 100644
index 000000000000..9f152be136aa
--- /dev/null
+++ b/app-arch/brotli/brotli-1.0.9-r2.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+DISTUTILS_OPTIONAL="1"
+DISTUTILS_IN_SOURCE_BUILD="1"
+
+inherit cmake-multilib distutils-r1
+
+DESCRIPTION="Generic-purpose lossless compression algorithm"
+HOMEPAGE="https://github.com/google/brotli"
+
+SLOT="0/$(ver_cut 1)"
+
+RDEPEND="python? ( ${PYTHON_DEPS} )"
+DEPEND="${RDEPEND}"
+
+IUSE="python static-libs test"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+LICENSE="MIT python? ( Apache-2.0 )"
+
+DOCS=( README.md CONTRIBUTING.md )
+
+if [[ ${PV} == "9999" ]] ; then
+	SRC_URI=""
+	EGIT_REPO_URI="https://github.com/google/${PN}.git"
+	inherit git-r3
+else
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x64-solaris"
+	SRC_URI="https://github.com/google/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+fi
+
+# tests are currently broken, see https://github.com/google/brotli/issues/850
+RESTRICT="test"
+
+PATCHES=(
+	"${FILESDIR}/${PV}-linker.patch"
+)
+
+src_prepare() {
+	use python && distutils-r1_src_prepare
+	cmake-utils_src_prepare
+}
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DBUILD_TESTING="$(usex test)"
+	)
+	cmake-utils_src_configure
+}
+src_configure() {
+	cmake-multilib_src_configure
+	use python && distutils-r1_src_configure
+}
+
+multilib_src_compile() {
+	cmake-utils_src_compile
+}
+src_compile() {
+	cmake-multilib_src_compile
+	use python && distutils-r1_src_compile
+}
+
+python_test() {
+	esetup.py test || die
+}
+
+multilib_src_test() {
+	cmake-utils_src_test
+}
+src_test() {
+	cmake-multilib_src_test
+	use python && distutils-r1_src_test
+}
+
+multilib_src_install() {
+	cmake-utils_src_install
+	use static-libs || rm "${ED}"/usr/$(get_libdir)/*.a || die
+}
+multilib_src_install_all() {
+	use python && distutils-r1_src_install
+}
diff --git a/app-arch/brotli/brotli-9999.ebuild b/app-arch/brotli/brotli-9999.ebuild
index d84bfa85b3e9..87affbe108c9 100644
--- a/app-arch/brotli/brotli-9999.ebuild
+++ b/app-arch/brotli/brotli-9999.ebuild
@@ -17,7 +17,7 @@ SLOT="0/$(ver_cut 1)"
 RDEPEND="python? ( ${PYTHON_DEPS} )"
 DEPEND="${RDEPEND}"
 
-IUSE="python test"
+IUSE="python static-libs test"
 REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
 
 LICENSE="MIT python? ( Apache-2.0 )"
@@ -29,7 +29,7 @@ if [[ ${PV} == "9999" ]] ; then
 	EGIT_REPO_URI="https://github.com/google/${PN}.git"
 	inherit git-r3
 else
-	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x64-solaris"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x64-solaris"
 	SRC_URI="https://github.com/google/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
 fi
 
@@ -73,6 +73,7 @@ src_test() {
 
 multilib_src_install() {
 	cmake-utils_src_install
+	use static-libs || rm "${ED}"/usr/$(get_libdir)/*.a || die
 }
 multilib_src_install_all() {
 	use python && distutils-r1_src_install
-- 
cgit v1.2.3