From 6b258729bdac916ff6e9a7d8c97b5fb7130edb86 Mon Sep 17 00:00:00 2001
From: Viorel Munteanu <ceamac@gentoo.org>
Date: Mon, 22 Apr 2024 19:10:27 +0300
Subject: app-misc/fastfetch: add 2.10.1

Signed-off-by: Viorel Munteanu <ceamac@gentoo.org>
---
 app-misc/fastfetch/Manifest                |   1 +
 app-misc/fastfetch/fastfetch-2.10.1.ebuild | 116 +++++++++++++++++++++++++++++
 2 files changed, 117 insertions(+)
 create mode 100644 app-misc/fastfetch/fastfetch-2.10.1.ebuild

diff --git a/app-misc/fastfetch/Manifest b/app-misc/fastfetch/Manifest
index 7ae1e46c6937..ec91ea6d3080 100644
--- a/app-misc/fastfetch/Manifest
+++ b/app-misc/fastfetch/Manifest
@@ -1,3 +1,4 @@
+DIST fastfetch-2.10.1.tar.gz 1315723 BLAKE2B 32c04836f2cbeab4cd4bdf0d3ae92ac19c5774b557dc4b1263aece03d494874a97743313a7d5a0722f2d37cc7e89968d577ad822a585c2b873e4e18721184712 SHA512 06b886afe2644434f7d629b07356d05c9d24382873348ab9b8d5375324fa89b8f0219883e4132e8ac1a7e50051d1f91bfdb9decd5c14f4d504bb17af2ecaabfb
 DIST fastfetch-2.7.1.tar.gz 1000565 BLAKE2B 061d2175bdca879bb4ef1a2f29fd73b99a7325fb8de66f05eb1203008c34ef20ff122e57a785ee0a5abb0251004023958abb1d158bc49cd1b34f9e02f3d1c6bc SHA512 55d897af532141d429aa5b58ab1516347f14597bf249b70f0d5ab27d11e235911858143fc32356255bef201cb44cdd7698e8d49094fb7e61c2e425a6c8ac5fa1
 DIST fastfetch-2.8.10.tar.gz 1290142 BLAKE2B 7a7ad65891850d96cc12d37b5e89359889afcdba6ccd30d834afd332ed072e00a719378ee3664a32b6e238fdca2fa1dc665768b078701b77837fefdacdce5027 SHA512 6b548c22239307f6dfcd90a4f995cbc77904adfd6f7ac809c7cd4c337a6783d768e2fd88d48e12c9b2c576893b74869d0a022f7129ccf37d853695ac3f5d488d
 DIST fastfetch-2.9.2.tar.gz 1294912 BLAKE2B 858c474d117903e990ecce4f1b9a7422da082beb79a360378ddefac1248224344a431218bb1d84b343f1ee96b044548f842ba4a04285f6e6aaaf442a92f8818b SHA512 be907b3080ff252e6c235798a6e3cb993b178a9ad02b9fd900816df560cff4f0351f212d0f00af31b671430115e5f635226bce004bb5efb7651a76f5e913a946
diff --git a/app-misc/fastfetch/fastfetch-2.10.1.ebuild b/app-misc/fastfetch/fastfetch-2.10.1.ebuild
new file mode 100644
index 000000000000..c3888b1ec46e
--- /dev/null
+++ b/app-misc/fastfetch/fastfetch-2.10.1.ebuild
@@ -0,0 +1,116 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="Fast neofetch-like system information tool"
+HOMEPAGE="https://github.com/fastfetch-cli/fastfetch"
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/fastfetch-cli/fastfetch.git"
+	[[ ${PV} == *0.1.9999 ]] && EGIT_BRANCH=master
+	[[ ${PV} == *0.2.9999 ]] && EGIT_BRANCH=dev
+	[[ "${EGIT_BRANCH}" == "" ]] && die "Please set a git branch"
+else
+	SRC_URI="https://github.com/fastfetch-cli/fastfetch/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+LICENSE="MIT nvidia-gpu? ( NVIDIA-NVLM )"
+SLOT="0"
+IUSE="X chafa dbus ddcutil drm gnome imagemagick networkmanager nvidia-gpu opencl opengl osmesa pulseaudio sqlite test vulkan wayland xcb xfce xrandr"
+RESTRICT="!test? ( test )"
+
+# note - qa-vdb will always report errors because fastfetch loads the libs dynamically
+# make sure to crank yyjson minimum version to match bundled version
+RDEPEND="
+	>=dev-libs/yyjson-0.9.0
+	sys-libs/zlib
+	X? ( x11-libs/libX11 )
+	chafa? ( media-gfx/chafa )
+	dbus? ( sys-apps/dbus )
+	ddcutil? ( app-misc/ddcutil:= )
+	drm? ( x11-libs/libdrm )
+	gnome? (
+		dev-libs/glib
+		gnome-base/dconf
+	)
+	imagemagick? ( media-gfx/imagemagick:= )
+	networkmanager? ( net-misc/networkmanager )
+	opencl? ( virtual/opencl )
+	opengl? ( media-libs/libglvnd[X] )
+	osmesa? ( media-libs/mesa[osmesa] )
+	pulseaudio? ( media-libs/libpulse )
+	sqlite? ( dev-db/sqlite:3 )
+	vulkan? (
+		media-libs/vulkan-loader
+		sys-apps/pciutils
+	)
+	wayland? ( dev-libs/wayland )
+	xcb? ( x11-libs/libxcb )
+	xfce? ( xfce-base/xfconf )
+	xrandr? ( x11-libs/libXrandr )
+"
+DEPEND="
+	${RDEPEND}
+	vulkan? ( dev-util/vulkan-headers )
+"
+BDEPEND="virtual/pkgconfig"
+
+REQUIRED_USE="
+	xrandr? ( X )
+	chafa? ( imagemagick )
+"
+
+src_configure() {
+	local fastfetch_enable_imagemagick7=no
+	local fastfetch_enable_imagemagick6=no
+	if use imagemagick; then
+		fastfetch_enable_imagemagick7=$(has_version '>=media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+		fastfetch_enable_imagemagick6=$(has_version '<media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+	fi
+
+	local mycmakeargs=(
+		-DENABLE_RPM=no
+		-DENABLE_ZLIB=yes
+		-DENABLE_SYSTEM_YYJSON=yes
+		-DIS_MUSL=$(usex elibc_musl)
+
+		-DENABLE_CHAFA=$(usex chafa)
+		-DENABLE_DBUS=$(usex dbus)
+		-DENABLE_DCONF=$(usex gnome)
+		-DENABLE_DDCUTIL=$(usex ddcutil)
+		-DENABLE_DRM=$(usex drm)
+		-DENABLE_EGL=$(usex opengl)
+		-DENABLE_GIO=$(usex gnome)
+		-DENABLE_GLX=$(usex opengl)
+		-DENABLE_IMAGEMAGICK6=${fastfetch_enable_imagemagick6}
+		-DENABLE_IMAGEMAGICK7=${fastfetch_enable_imagemagick7}
+		-DENABLE_LIBNM=$(usex networkmanager)
+		-DENABLE_PROPRIETARY_GPU_DRIVER_API=$(usex nvidia-gpu)
+		-DENABLE_OPENCL=$(usex opencl)
+		-DENABLE_OSMESA=$(usex osmesa)
+		-DENABLE_PULSE=$(usex pulseaudio)
+		-DENABLE_SQLITE3=$(usex sqlite)
+		-DENABLE_VULKAN=$(usex vulkan)
+		-DENABLE_WAYLAND=$(usex wayland)
+		-DENABLE_X11=$(usex X)
+		-DENABLE_XCB=$(usex xcb)
+		-DENABLE_XCB_RANDR=$(usex xcb)
+		-DENABLE_XFCONF=$(usex xfce)
+		-DENABLE_XRANDR=$(usex xrandr)
+		-DBUILD_TESTS=$(usex test)
+	)
+
+	append-cppflags -DNDEBUG
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	rm -r "${ED}"/usr/share/licenses || die
+}
-- 
cgit v1.2.3-65-gdbad