From 6c5a74a1c6b30ad867f8b33f8ffd89f293063c1e Mon Sep 17 00:00:00 2001
From: Jeroen Roovers <jer@gentoo.org>
Date: Fri, 15 Mar 2019 16:00:20 +0100
Subject: dev-libs/libuv: Add live ebuild

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Jeroen Roovers <jer@gentoo.org>
---
 dev-libs/libuv/libuv-9999.ebuild | 47 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 dev-libs/libuv/libuv-9999.ebuild

diff --git a/dev-libs/libuv/libuv-9999.ebuild b/dev-libs/libuv/libuv-9999.ebuild
new file mode 100644
index 000000000000..5e8f4c3920c3
--- /dev/null
+++ b/dev-libs/libuv/libuv-9999.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools git-r3 multilib-minimal
+
+DESCRIPTION="Cross-platform asychronous I/O"
+HOMEPAGE="https://github.com/libuv/libuv"
+EGIT_REPO_URI="${HOMEPAGE}"
+
+LICENSE="BSD BSD-2 ISC MIT"
+SLOT="0/1"
+KEYWORDS=""
+IUSE="static-libs"
+RESTRICT="test"
+
+DEPEND="sys-devel/libtool
+	virtual/pkgconfig[${MULTILIB_USEDEP}]"
+
+src_prepare() {
+	default
+
+	echo "m4_define([UV_EXTRA_AUTOMAKE_FLAGS], [serial-tests])" \
+		> m4/libuv-extra-automake-flags.m4 || die
+
+	# upstream fails to ship a configure script
+	eautoreconf
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		cc_cv_cflags__g=no
+		$(use_enable static-libs static)
+	)
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_test() {
+	mkdir "${BUILD_DIR}"/test || die
+	cp -pPR "${S}"/test/fixtures "${BUILD_DIR}"/test/fixtures || die
+	default
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	find "${D}" -name '*.la' -delete || die
+}
-- 
cgit v1.2.3