From 7d8979be42cabdcacc64663d28be3108c3cd89a2 Mon Sep 17 00:00:00 2001
From: Michał Górny <mgorny@gentoo.org>
Date: Sun, 31 Jan 2021 09:57:59 +0100
Subject: dev-python/gitdb: Remove smmap upper bound
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Closes: https://bugs.gentoo.org/767970
Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/gitdb/gitdb-4.0.5-r1.ebuild | 62 ++++++++++++++++++++++++++++++++++
 dev-python/gitdb/gitdb-4.0.5.ebuild    | 55 ------------------------------
 2 files changed, 62 insertions(+), 55 deletions(-)
 create mode 100644 dev-python/gitdb/gitdb-4.0.5-r1.ebuild
 delete mode 100644 dev-python/gitdb/gitdb-4.0.5.ebuild

diff --git a/dev-python/gitdb/gitdb-4.0.5-r1.ebuild b/dev-python/gitdb/gitdb-4.0.5-r1.ebuild
new file mode 100644
index 000000000000..9b989f33a302
--- /dev/null
+++ b/dev-python/gitdb/gitdb-4.0.5-r1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+
+inherit distutils-r1
+
+DESCRIPTION="GitDB is a pure-Python git object database"
+HOMEPAGE="
+	https://github.com/gitpython-developers/gitdb
+	https://pypi.org/project/gitdb/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 ~arm arm64 x86"
+
+RDEPEND="
+	>=dev-python/smmap-3.0.1[${PYTHON_USEDEP}]"
+BDEPEND="
+	test? (
+		dev-vcs/git
+	)"
+
+distutils_enable_tests nose
+
+src_prepare() {
+	# remove unnecessary version restriction
+	# https://github.com/gitpython-developers/gitdb/issues/67
+	sed -i -e '/smmap/s:,<4::' setup.py || die
+	distutils-r1_src_prepare
+}
+
+src_test() {
+	local i
+
+	mkdir "${T}"/repo || die
+	cd "${T}"/repo || die
+
+	for (( i = 0; i < 2500; ++i )); do
+		echo "${i}" > file"${i}" || die
+	done
+
+	git init || die
+	git config user.email "you@example.com" || die
+	git config user.name "Your Name" || die
+	git add -A || die
+	git commit -q -m ".." || die
+	git clone --bare "${T}"/repo "${T}"/repo.git || die
+	cd "${S}" || die
+
+	distutils-r1_src_test
+}
+
+python_test() {
+	#TRAVIS=1 disables performance tests which rely on the gitdb repo
+	local -x TRAVIS=1
+	local -x GITDB_TEST_GIT_REPO_BASE="${T}"/repo.git
+	nosetests -v || die "Tests fail with ${EPYTHON}"
+}
diff --git a/dev-python/gitdb/gitdb-4.0.5.ebuild b/dev-python/gitdb/gitdb-4.0.5.ebuild
deleted file mode 100644
index 22051202ac73..000000000000
--- a/dev-python/gitdb/gitdb-4.0.5.ebuild
+++ /dev/null
@@ -1,55 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-PYTHON_COMPAT=( python3_{7..9} )
-
-inherit distutils-r1
-
-DESCRIPTION="GitDB is a pure-Python git object database"
-HOMEPAGE="
-	https://github.com/gitpython-developers/gitdb
-	https://pypi.org/project/gitdb/"
-SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="amd64 ~arm arm64 x86"
-
-RDEPEND="
-	>=dev-python/smmap-3.0.1[${PYTHON_USEDEP}]"
-BDEPEND="
-	test? (
-		dev-vcs/git
-	)"
-
-distutils_enable_tests nose
-
-src_test() {
-	local i
-
-	mkdir "${T}"/repo || die
-	cd "${T}"/repo || die
-
-	for (( i = 0; i < 2500; ++i )); do
-		echo "${i}" > file"${i}" || die
-	done
-
-	git init || die
-	git config user.email "you@example.com" || die
-	git config user.name "Your Name" || die
-	git add -A || die
-	git commit -q -m ".." || die
-	git clone --bare "${T}"/repo "${T}"/repo.git || die
-	cd "${S}" || die
-
-	distutils-r1_src_test
-}
-
-python_test() {
-	#TRAVIS=1 disables performance tests which rely on the gitdb repo
-	local -x TRAVIS=1
-	local -x GITDB_TEST_GIT_REPO_BASE="${T}"/repo.git
-	nosetests -v || die "Tests fail with ${EPYTHON}"
-}
-- 
cgit v1.2.3-65-gdbad