From 8a57165b5b98e4ffb14efcbb704cf820cabe292e Mon Sep 17 00:00:00 2001
From: Matt Turner <mattst88@gentoo.org>
Date: Fri, 29 Jul 2022 14:33:01 -0400
Subject: dev-libs/libwacom: Version bump to 2.4.0

Signed-off-by: Matt Turner <mattst88@gentoo.org>
---
 dev-libs/libwacom/Manifest              |  1 +
 dev-libs/libwacom/libwacom-2.4.0.ebuild | 71 +++++++++++++++++++++++++++++++++
 2 files changed, 72 insertions(+)
 create mode 100644 dev-libs/libwacom/libwacom-2.4.0.ebuild

diff --git a/dev-libs/libwacom/Manifest b/dev-libs/libwacom/Manifest
index 69430b2c6c53..e0aa03eac170 100644
--- a/dev-libs/libwacom/Manifest
+++ b/dev-libs/libwacom/Manifest
@@ -1,2 +1,3 @@
 DIST libwacom-1.12.tar.bz2 543819 BLAKE2B fdbfba23d7b1e047757b0c0ff698a484cadc91c199459e1da49bfd5a5406aeb62d2ca43856f7d8363c3f36c7c05f4d3160e8fb576c3d18f085144dec259d49c5 SHA512 4e0084eda01e78f52336f3f1f1ea3ea86cb9c5fdd6d6c0316662405ebe2a328d6837f8db855e58f5fa95a640a5d456a081a7de339a372bf851bc0d5c69530379
 DIST libwacom-2.3.0.tar.xz 107872 BLAKE2B 5589067eabb0b0d5384015a0200950146d1c028ce8cd870b845de8ec22ca1710645755253952e49f9c1db585a945c6ea8da37318b900f16602a1a7081512ecd9 SHA512 ccbeddc55cc67d8102aa4536616f3c379877ba9154a72d7ad92941854c79b727a21efacf4282b9a8730ff181d094749bf84a9fe5850de6246d91a17e5029d888
+DIST libwacom-2.4.0.tar.xz 108812 BLAKE2B 18f41cd052b18c652c61062948355b4738afe57db344749055492cc6853bcbe3048c582a72318891727ec0fb01a7799f4c80c544b37b51c9246f98e5ae3fef1b SHA512 c67b8a81e9f4285a4e6f422b29e9b8b3677e3fc45e5190fd2b95ad361e5ef35e124b7d78bcf2bb9d7b7183525a6be9916b3038714c42c9ef405a1075750465f3
diff --git a/dev-libs/libwacom/libwacom-2.4.0.ebuild b/dev-libs/libwacom/libwacom-2.4.0.ebuild
new file mode 100644
index 000000000000..450f5ceeff32
--- /dev/null
+++ b/dev-libs/libwacom/libwacom-2.4.0.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+inherit meson python-any-r1 udev
+
+DESCRIPTION="Library for identifying Wacom tablets and their model-specific features"
+HOMEPAGE="https://github.com/linuxwacom/libwacom"
+SRC_URI="https://github.com/linuxwacom/${PN}/releases/download/${P}/${P}.tar.xz"
+
+LICENSE="MIT"
+SLOT="0/9" # libwacom SONAME
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/glib:2
+	dev-libs/libgudev:=
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+	test? (
+		${PYTHON_DEPS}
+		$(python_gen_any_dep '
+			dev-python/python-libevdev[${PYTHON_USEDEP}]
+			dev-python/pyudev[${PYTHON_USEDEP}]
+			dev-python/pytest[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+python_check_deps() {
+	has_version -b "dev-python/python-libevdev[${PYTHON_USEDEP}]" &&
+	has_version -b "dev-python/pyudev[${PYTHON_USEDEP}]" &&
+	has_version -b "dev-python/pytest[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	if use test; then
+		python-any-r1_pkg_setup
+	fi
+}
+
+src_prepare() {
+	default
+
+	# Don't call systemd daemon-reload in the test suite
+	sed -i -e '/daemon-reload/d' test/test_udev_rules.py || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature doc documentation)
+		$(meson_feature test tests)
+		-Dudev-dir=$(get_udevdir)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	udev_reload
+}
+
+pkg_postrm() {
+	udev_reload
+}
-- 
cgit v1.2.3-65-gdbad