From 8c791b9cc1caf8d2f5a4e6b2f2da97984c7f23a5 Mon Sep 17 00:00:00 2001
From: Miroslav Šulc <fordfrog@gentoo.org>
Date: Thu, 8 Jun 2023 07:49:13 +0200
Subject: media-sound/qtractor: bump to 0.9.34
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>
---
 media-sound/qtractor/Manifest               |   1 +
 media-sound/qtractor/qtractor-0.9.34.ebuild | 108 ++++++++++++++++++++++++++++
 2 files changed, 109 insertions(+)
 create mode 100644 media-sound/qtractor/qtractor-0.9.34.ebuild

diff --git a/media-sound/qtractor/Manifest b/media-sound/qtractor/Manifest
index 4ee19d1bf82d..35a73c554a2c 100644
--- a/media-sound/qtractor/Manifest
+++ b/media-sound/qtractor/Manifest
@@ -1 +1,2 @@
 DIST qtractor-0.9.33.tar.gz 2014555 BLAKE2B b2de591c8be935403f8c54682758a891bd9ead07626aede7d1015915941a0558e9f9aeeed3cda5b2b60c52637a80d72e10edc6d29c5d05d87bcfaca31df58e7a SHA512 cb5f26e124a3b43afeaa7f175338ea54ffdd907ee95935c9188ed890afbfea7706fcd45cf6f3c208abfd93ddfbc1ec6fbd1ee2c11a5505f45c97d98950944811
+DIST qtractor-0.9.34.tar.gz 2012437 BLAKE2B c64b75bc8ecd761378dd0170e0fdcfcd5c612cabdf8c4dddcfaca2bbbd95db6328b36bfe1a10426744b9e75148263476bc17af80efcecf70a6c6a2b4089f7c26 SHA512 6ee5df583eb7e46c88aacb98d0dc79159b50e510158651d476e9516180e9bcb536e9642842714b62f7c4fde15fe386d85e6706f70b583ce0d8677e671985c695
diff --git a/media-sound/qtractor/qtractor-0.9.34.ebuild b/media-sound/qtractor/qtractor-0.9.34.ebuild
new file mode 100644
index 000000000000..0a0f707f34eb
--- /dev/null
+++ b/media-sound/qtractor/qtractor-0.9.34.ebuild
@@ -0,0 +1,108 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg
+
+DESCRIPTION="Audio/MIDI multi-track sequencer written in C++ with the Qt framework"
+HOMEPAGE="https://qtractor.sourceforge.io"
+SRC_URI="mirror://sourceforge/qtractor/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="aubio cpu_flags_x86_sse debug dssi ladspa libsamplerate mad osc rubberband vorbis zlib"
+REQUIRED_USE="dssi? ( ladspa )"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig
+"
+DEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	dev-qt/qtx11extras:5
+	media-libs/alsa-lib
+	media-libs/libsndfile
+	media-libs/lilv
+	media-libs/lv2
+	media-libs/suil
+	virtual/jack
+	x11-libs/libxcb:=
+	aubio? ( media-libs/aubio:= )
+	dssi? ( media-libs/dssi )
+	ladspa? ( media-libs/ladspa-sdk )
+	libsamplerate? ( media-libs/libsamplerate )
+	mad? ( media-libs/libmad )
+	osc? ( media-libs/liblo )
+	rubberband? ( media-libs/rubberband )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+	zlib? ( sys-libs/zlib )
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCONFIG_DSSI=$(usex dssi 1 0)
+		-DCONFIG_GRADIENT=1
+		-DCONFIG_JACK_LATENCY=1
+		-DCONFIG_JACK_METADATA=1
+		-DCONFIG_JACK_SESSION=1
+		-DCONFIG_LADSPA=$(usex ladspa 1 0)
+		-DCONFIG_LIBAUBIO=$(usex aubio 1 0)
+		-DCONFIG_LIBLILV=1
+		-DCONFIG_LIBLO=$(usex osc 1 0)
+		-DCONFIG_LIBMAD=$(usex mad 1 0)
+		-DCONFIG_LIBRUBBERBAND=$(usex rubberband 1 0)
+		-DCONFIG_LIBSAMPLERATE=$(usex libsamplerate 1 0)
+		-DCONFIG_LIBVORBIS=$(usex vorbis 1 0)
+		-DCONFIG_LIBZ=$(usex zlib 1 0)
+		-DCONFIG_LV2=1
+		-DCONFIG_LV2_UI_GTK2=0
+		-DCONFIG_NSM=0
+		-DCONFIG_SSE=$(usex cpu_flags_x86_sse 1 0)
+		-DCONFIG_STACKTRACE=$(usex debug 1 0)
+		-DCONFIG_VESTIGE=1
+		-DCONFIG_VST2=1
+		-DCONFIG_VST3=0
+		-DCONFIG_XUNIQUE=0
+	)
+	# Following options are left to the default
+	# CONFIG_LV2_ATOM
+	# CONFIG_LV2_BUF_SIZE
+	# CONFIG_LV2_CVPORT
+	# CONFIG_LV2_EVENT
+	# CONFIG_LV2_EXTERNAL_UI
+	# CONFIG_LV2_MIDNAM
+	# CONFIG_LV2_OPTIONS
+	# CONFIG_LV2_PARAMETERS
+	# CONFIG_LV2_PATCH
+	# CONFIG_LV2_PORT_EVENT
+	# CONFIG_LV2_PRESETS
+	# CONFIG_LV2_PROGRAMS
+	# CONFIG_LV2_STATE
+	# CONFIG_LV2_STATE_FILES
+	# CONFIG_LV2_STATE_MAKE_PATH
+	# CONFIG_LV2_TIME
+	# CONFIG_LV2_TIME_POSITION
+	# CONFIG_LV2_UI
+	# CONFIG_LV2_UI_IDLE
+	# CONFIG_LV2_UI_REQ_VALUE
+	# CONFIG_LV2_UI_SHOW
+	# CONFIG_LV2_UI_TOUCH
+	# CONFIG_LV2_WORKER
+	# CONFIG_LV2_UI_X11
+	cmake_src_configure
+}
-- 
cgit v1.2.3-65-gdbad