From 8d40e5767c67082e1f69117553766ad1a3614354 Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Wed, 20 Jun 2018 14:22:49 +0200
Subject: dev-libs/quazip: 0.7.6 version bump, moved to GitHub

Bug: https://bugs.gentoo.org/658548
Package-Manager: Portage-2.3.40, Repoman-2.3.9
---
 dev-libs/quazip/Manifest            |  1 +
 dev-libs/quazip/quazip-0.7.6.ebuild | 48 +++++++++++++++++++++++++++++++++++++
 2 files changed, 49 insertions(+)
 create mode 100644 dev-libs/quazip/quazip-0.7.6.ebuild

diff --git a/dev-libs/quazip/Manifest b/dev-libs/quazip/Manifest
index d767f3003b23..15bd2a691672 100644
--- a/dev-libs/quazip/Manifest
+++ b/dev-libs/quazip/Manifest
@@ -1 +1,2 @@
 DIST quazip-0.7.3.tar.gz 439536 BLAKE2B 7b91d12f14e060f3554e6d9b4041aef56f269c3e5cc3a4e67eaa415cf990f474da8581a248037d2b741117c5f83c514f3dc4e30310dccc954cf363435acfc4c6 SHA512 d4b55bd040e47e97e7bd5d080399ae4aa5fbc4985d6ab5979b468abc852c91b2e3e5d35af90d4b4de3bb01ea9135d0247473d6eab0413392b1c8567dc799a9fe
+DIST quazip-0.7.6.tar.gz 149029 BLAKE2B 7eb99f550dc06d8d2911b22214294accaa5126657598bfd60614267715ea968790f470cea2820e1a78a8581ab0d4b75c90589c0da1ae815067e083e389020762 SHA512 4325a69918216bb66c6a7c53589ef73473c3752151522a135dd9c92dbf722b29656aea7be0314c84399a214391eca79296ecda5811ab31845d8cf53c010110d1
diff --git a/dev-libs/quazip/quazip-0.7.6.ebuild b/dev-libs/quazip/quazip-0.7.6.ebuild
new file mode 100644
index 000000000000..e9f4d698d203
--- /dev/null
+++ b/dev-libs/quazip/quazip-0.7.6.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils flag-o-matic qmake-utils
+
+DESCRIPTION="Simple C++ wrapper over Gilles Vollant's ZIP/UNZIP package"
+HOMEPAGE="https://stachenov.github.io/quazip/"
+SRC_URI="https://github.com/stachenov/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1-with-linking-exception"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="static-libs"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtnetwork:5
+	sys-libs/zlib[minizip]
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	if ! use static-libs ; then
+		sed -e "/^install/ s/quazip_static//" -i CMakeLists.txt || die
+	fi
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local libdir=$(get_libdir)
+	local -x CXXFLAGS="${CXXFLAGS}"
+	append-cxxflags -std=c++11 -fPIC
+
+	local mycmakeargs=(
+		-DBUILD_WITH_QT4=OFF
+		-DLIB_SUFFIX=${libdir/lib/}
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	# compatibility with not yet fixed rdeps (Gentoo bug #598136)
+	dosym libquazip5.so /usr/$(get_libdir)/libquazip.so
+}
-- 
cgit v1.2.3-65-gdbad