From 8e1bf48a0f30b20662d158e1a14127c0749f57d2 Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Fri, 3 Sep 2021 08:38:13 +0200
Subject: media-gfx/exiv2: Drop vulnerable 0.27.3

Bug: https://bugs.gentoo.org/785646
Package-Manager: Portage-3.0.22, Repoman-3.0.3
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 media-gfx/exiv2/Manifest            |   1 -
 media-gfx/exiv2/exiv2-0.27.3.ebuild | 102 ------------------------------------
 2 files changed, 103 deletions(-)
 delete mode 100644 media-gfx/exiv2/exiv2-0.27.3.ebuild

diff --git a/media-gfx/exiv2/Manifest b/media-gfx/exiv2/Manifest
index ff5c5104d27d..c1330ee124bc 100644
--- a/media-gfx/exiv2/Manifest
+++ b/media-gfx/exiv2/Manifest
@@ -1,2 +1 @@
-DIST exiv2-0.27.3-Source.tar.gz 26447901 BLAKE2B ac13e6d8fce83923278cfeb628f143310a3c62b42936c8ed8b302a2c3df4c36f5666fa749adfb1d745e42da8f519762532e6fc281993aa55bcd7ce56e08c6e3e SHA512 3f5758ee862b811eeb89cc75fc2bbd8bf10329efa2ce1e68555cdc7729faa6cfd1603e0cc859fbdbe6d8fd5e53bd9b9e6d869d8a20ed17497bf87ce78c005de9
 DIST exiv2-0.27.4-Source.tar.gz 32055837 BLAKE2B 9c31c08fafb38895fa7812a8c7a195335e80a6b9c15f7b5f3750f5ab30903c4c3bbf9aee5a7293a7d437d15a49a9cb7b45a3133cbb36ee62081efae0dd67b61a SHA512 f6798baafb36a54ba5bc65c2d28d4f4469e298582c90b417eb437b5dbda8e11963fb3314e8419717b3815ee8c3a68955cddc79e45351d9f2c165a0b73eb7b7be
diff --git a/media-gfx/exiv2/exiv2-0.27.3.ebuild b/media-gfx/exiv2/exiv2-0.27.3.ebuild
deleted file mode 100644
index 245e6ec2e29e..000000000000
--- a/media-gfx/exiv2/exiv2-0.27.3.ebuild
+++ /dev/null
@@ -1,102 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-if [[ ${PV} = *9999 ]]; then
-	EGIT_REPO_URI="https://github.com/Exiv2/exiv2.git"
-	inherit git-r3
-else
-	SRC_URI="https://exiv2.org/builds/${P}-Source.tar.gz"
-	KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~mips ppc ppc64 ~s390 sparc x86 ~amd64-linux ~x86-linux ~x64-solaris ~x86-solaris"
-	S="${WORKDIR}/${P}-Source"
-fi
-
-CMAKE_ECLASS=cmake
-PYTHON_COMPAT=( python3_{7,8,9} )
-inherit cmake-multilib python-any-r1
-
-DESCRIPTION="EXIF, IPTC and XMP metadata C++ library and command line utility"
-HOMEPAGE="https://www.exiv2.org/"
-
-LICENSE="GPL-2"
-SLOT="0/27"
-IUSE="doc examples nls +png webready +xmp"
-
-BDEPEND="
-	doc? (
-		${PYTHON_DEPS}
-		app-doc/doxygen
-		dev-libs/libxslt
-		media-gfx/graphviz
-		virtual/pkgconfig
-	)
-	nls? ( sys-devel/gettext )
-"
-DEPEND="
-	>=virtual/libiconv-0-r1[${MULTILIB_USEDEP}]
-	nls? ( >=virtual/libintl-0-r1[${MULTILIB_USEDEP}] )
-	png? ( sys-libs/zlib[${MULTILIB_USEDEP}] )
-	webready? (
-		>net-libs/libssh-0.9.1[${MULTILIB_USEDEP}]
-		net-misc/curl[${MULTILIB_USEDEP}]
-	)
-	xmp? ( dev-libs/expat[${MULTILIB_USEDEP}] )
-"
-RDEPEND="${DEPEND}"
-
-DOCS=( README.md doc/ChangeLog doc/cmd.txt )
-
-pkg_setup() {
-	use doc && python-any-r1_pkg_setup
-}
-
-src_prepare() {
-	# FIXME @upstream:
-	einfo "Converting doc/cmd.txt to UTF-8"
-	iconv -f LATIN1 -t UTF-8 doc/cmd.txt > doc/cmd.txt.tmp || die
-	mv -f doc/cmd.txt.tmp doc/cmd.txt || die
-
-	cmake_src_prepare
-
-	sed -e "/^include.*compilerFlags/s/^/#DONT /" -i CMakeLists.txt || die
-}
-
-multilib_src_configure() {
-	local mycmakeargs=(
-		-DCMAKE_CXX_STANDARD=14
-		-DEXIV2_BUILD_SAMPLES=NO
-		-DEXIV2_BUILD_PO=$(usex nls)
-		-DEXIV2_ENABLE_NLS=$(usex nls)
-		-DEXIV2_ENABLE_PNG=$(usex png)
-		-DEXIV2_ENABLE_CURL=$(usex webready)
-		-DEXIV2_ENABLE_SSH=$(usex webready)
-		-DEXIV2_ENABLE_WEBREADY=$(usex webready)
-		-DEXIV2_ENABLE_XMP=$(usex xmp)
-		$(multilib_is_native_abi || echo -DEXIV2_BUILD_EXIV2_COMMAND=NO)
-		$(multilib_is_native_abi && echo -DEXIV2_BUILD_DOC=$(usex doc))
-		-DCMAKE_INSTALL_DOCDIR="${EPREFIX}"/usr/share/doc/${PF}/html
-	)
-
-	cmake_src_configure
-}
-
-multilib_src_compile() {
-	cmake_src_compile
-
-	if multilib_is_native_abi; then
-		use doc && eninja doc
-	fi
-}
-
-multilib_src_install_all() {
-	use xmp && DOCS+=( doc/{COPYING-XMPSDK,README-XMP,cmdxmp.txt} )
-
-	einstalldocs
-	find "${D}" -name '*.la' -delete || die
-
-	if use examples; then
-		docinto examples
-		dodoc samples/*.cpp
-	fi
-}
-- 
cgit v1.2.3-65-gdbad